Differential D28152 Diff 80513 kcmkwin/kwinrules/package/contents/ui/ValueEditor.qml

Changeset View

Standalone View

View Options

kcmkwin/kwinrules/package/contents/ui/ValueEditor.qml

  • This file was added.
1​/*
2​ * Copyright (c) 2020 Ismael Asensio <isma.af@gmail.com>
3​ *
4​ * This program is free software; you can redistribute it and/or
5​ * modify it under the terms of the GNU General Public License as
6​ * published by the Free Software Foundation; either version 2 of
7​ * the License or (at your option) version 3 or any later version
8​ * accepted by the membership of KDE e.V. (or its successor approved
9​ * by the membership of KDE e.V.), which shall act as a proxy
10​ * defined in Section 14 of version 3 of the license.
11​ *
12​ * This program is distributed in the hope that it will be useful,
13​ * but WITHOUT ANY WARRANTY; without even the implied warranty of
14​ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15​ * GNU General Public License for more details.
16​ *
17​ * You should have received a copy of the GNU General Public License
18​ * along with this program. If not, see <http://www.gnu.org/licenses/>.
19​ */
20​
21​import QtQuick 2.14
22​import QtQuick.Layouts 1.14
23​import QtQuick.Controls 2.14 as QQC2
24​
25​import org.kde.kirigami 2.10 as Kirigami
26​import org.kde.kquickcontrols 2.0 as KQC
27​import org.kde.kcms.kwinrules 1.0
28​
29​
30​Loader {
31​ id: valueEditor
32​ focus: true
33​
34​ property var ruleValue
35​ property var ruleOptions
36​ property int controlType
37​
38​ signal valueEdited(var value)
39​
40​ sourceComponent: {
41​ switch (controlType) {
42​ case RuleItem.Boolean: return booleanEditor
43​ case RuleItem.String: return stringEditor
44​ case RuleItem.Integer: return integerEditor
45​ case RuleItem.Option: return optionEditor
46​ case RuleItem.FlagsOption: return flagsEditor
47​ case RuleItem.Percentage: return percentageEditor
48​ case RuleItem.Coordinate: return coordinateEditor
49​ case RuleItem.Shortcut: return shortcutEditor
50​ default: return emptyEditor
51​ }
52​ }
53​
54​ Component {
55​ id: emptyEditor
56​ Item {}
57​ }
58​
59​ Component {
60​ id: booleanEditor
61​ RowLayout {
62​ Item {
63​ Layout.fillWidth: true
64​ }
65​ QQC2.RadioButton {
66​ text: i18n("Yes")
67​ checked: ruleValue
68​ Layout.margins: Kirigami.Units.smallSpacing
69​ onToggled: valueEditor.valueEdited(checked)
70​ }
71​ QQC2.RadioButton {
72​ text: i18n("No")
73​ checked: !ruleValue
74​ Layout.margins: Kirigami.Units.smallSpacing
75​ onToggled: valueEditor.valueEdited(!checked)
76​ }
77​ }
78​ }
79​
80​ Component {
81​ id: stringEditor
82​ QQC2.TextField {
83​ property bool isTextEdited: false
84​ text: ruleValue
85​ horizontalAlignment: Text.AlignLeft
86​ onTextEdited: { isTextEdited = true; }
87​ onEditingFinished: {
88​ if (isTextEdited) { valueEditor.valueEdited(text); }
89​ isTextEdited = false;
90​ }
91​ }
92​ }
93​
94​ Component {
95​ id: integerEditor
96​ QQC2.SpinBox {
97​ editable: true
98​ value: ruleValue
99​ onValueModified: valueEditor.valueEdited(value)
100​ }
101​ }
102​
103​ Component {
104​ id: optionEditor
105​ OptionsComboBox {
106​ flat: true
107​ model: ruleOptions
108​ onActivated: (index) => {
109​ valueEditor.valueEdited(currentValue);
110​ }
111​ }
112​ }
113​
114​ Component {
115​ id: flagsEditor
116​ OptionsComboBox {
117​ flat: true
118​ model: ruleOptions
119​ multipleChoice: true
120​ selectionMask: ruleValue
121​ onActivated: {
122​ valueEditor.valueEdited(selectionMask);
123​ }
124​ }
125​ }
126​
127​ Component {
128​ id: percentageEditor
129​ RowLayout {
130​ QQC2.Slider {
131​ id: slider
132​ Layout.fillWidth: true
133​ from: 0
134​ to: 100
135​ value: ruleValue
136​ onMoved: valueEditor.valueEdited(Math.round(slider.value))
137​ }
ngrahamUnsubmitted
Done

Give this a minimum width, or else the rowlayout gets wider with every digit added to the number and resizes the combobox next to it

ngraham: Give this a minimum width, or else the rowlayout gets wider with every digit added to the…
138​ QQC2.Label {
139​ text: i18n("%1 %", Math.round(slider.value))
140​ horizontalAlignment: Qt.AlignRight
ngrahamUnsubmitted
Not Done

Needs to be a bit bigger; the text still expands when set to 100%.

ngraham: Needs to be a bit bigger; the text still expands when set to 100%.
iasensioAuthorUnsubmitted
Not Done

Ok. I might have a slightly smaller font.
Is there a not very hackish way the get the width for "100%" with user's font?

iasensio: Ok. I might have a slightly smaller font. Is there a not very hackish way the get the width…
ngrahamUnsubmitted
Done

Allow me to introduce you to TextMetrics! It can be used for exactly this. Elisa uses it all over the place for just this purpose.

ngraham: Allow me to introduce you to `TextMetrics`! It can be used for exactly this. Elisa uses it all…
141​ Layout.minimumWidth: maxPercentage.width + Kirigami.Units.smallSpacing
142​ Layout.margins: Kirigami.Units.smallSpacing
143​ }
144​ TextMetrics {
145​ id: maxPercentage
146​ text: i18n("%1 %", 100)
147​ }
148​ }
149​ }
150​
151​ Component {
152​ id: coordinateEditor
153​ RowLayout {
154​ id: coordItem
155​ spacing: Kirigami.Units.smallSpacing
156​
157​ property var coords: ruleValue ? ruleValue.split(',') : [0, 0]
158​
159​ QQC2.SpinBox {
160​ id: coordX
161​ editable: true
162​ Layout.preferredWidth: 50 // 50%
163​ Layout.fillWidth: true
164​ from: 0
165​ to: 4098
166​ value: coords[0]
167​ onValueModified: valueEditor.valueEdited(coordX.value + "," + coordY.value)
168​ }
169​ QQC2.Label {
170​ id: coordSeparator
171​ Layout.preferredWidth: implicitWidth
172​ text: i18nc("(x, y) coordinates separator in size/position","x")
173​ horizontalAlignment: Text.AlignHCenter
174​ }
175​ QQC2.SpinBox {
176​ id: coordY
177​ editable: true
178​ from: 0
179​ to: 4098
180​ Layout.preferredWidth: 50 // 50%
181​ Layout.fillWidth: true
182​ value: coords[1]
183​ onValueModified: valueEditor.valueEdited(coordX.value + "," + coordY.value)
184​ }
185​ }
186​ }
187​
188​ Component {
189​ id: shortcutEditor
190​ RowLayout {
191​ Item {
192​ Layout.fillWidth: true
193​ }
194​ KQC.KeySequenceItem {
195​ keySequence: ruleValue
196​ onCaptureFinished: valueEditor.valueEdited(keySequence)
197​ }
198​ }
199​ }
200​}