Differential D4077 Diff 10033 plugins/welcomepage/qml/NewsFeed.qml

Changeset View

Standalone View

View Options

plugins/welcomepage/qml/NewsFeed.qml

  • This file was added.
1​/* KDevelop
2​ *
3​ * Copyright 2017 Kevin Funk <kfunk@kde.org>
4​ *
5​ * This program is free software; you can redistribute it and/or
6​ * modify it under the terms of the GNU General Public License
7​ * as published by the Free Software Foundation; either version 2
8​ * of the License, or (at your option) any later version.
9​ *
10​ * This program is distributed in the hope that it will be useful,
11​ * but WITHOUT ANY WARRANTY; without even the implied warranty of
12​ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
13​ * GNU General Public License for more details.
14​ *
15​ * You should have received a copy of the GNU General Public License
16​ * along with this program; if not, write to the Free Software
17​ * Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
18​ * 02110-1301, USA.
19​ */
20​
21​import QtQuick 2.0
22​import QtQuick.Controls 1.3
23​import QtQuick.Layouts 1.2
24​import QtQuick.XmlListModel 2.0
25​
26​import "storage.js" as Storage
27​
28​ListView {
29​ id: root
30​
31​ /// Update interval (in minutes) in which the news feed is polled
32​ property int updateInterval: 24 * 60 * 1000
33​ /// Max age (in minutes) of a news entry so it is shown in the list view
34​ /// TODO: Implement me
35​ property int maxNewsAge: 3 * 30 * 24 * 60 // 3 months
36​ /// Max age (in minutes) of a news entry so it is considered 'new' (thus highlighted with a bold font)
37​ property int maxHighlightedNewsAge: 30 * 24 * 60 // a month
38​
39​ readonly property string feedUrl: "https://www.kdevelop.org/news/feed"
40​ readonly property bool loading: newsFeedSyncModel.status === XmlListModel.Loading
41​
42​ /// Returns a date parsed from the pubDate
43​ function parsePubDate(pubDate) {
44​ // We need to modify the pubDate read from the RSS feed
45​ // so the JavaScript Date object can interpret it
46​ var d = pubDate.replace(',','').split(' ');
47​ if (d.length != 6)
48​ return new Date(NaN);
49​
50​ return new Date([d[0], d[2], d[1], d[3], d[4], 'GMT' + d[5]].join(' '));
51​ }
52​
53​ function minutesSince(date) {
54​ return !isNaN(date) ? Math.floor(Number((new Date() - date)) / 60000) : -1;
55​ }
56​
57​ function loadFromCache() {
58​ var data = Storage.get("newsFeedOfflineModelData", null);
59​ if (data) {
60​ var newsEntries = JSON.parse(data);
61​ for (var i = 0; i < newsEntries.length; ++i) {
62​ newsFeedOfflineModel.append(newsEntries[i]);
63​ }
64​ }
65​ }
66​ function saveToCache() {
67​ var newsEntries = [];
68​ for (var i = 0; i < newsFeedSyncModel.count; ++i) {
69​ var entry = newsFeedSyncModel.get(i);
70​ newsEntries.push({"title" : entry.title, "link" : entry.link, "pubDate" : entry.pubDate});
71​ }
72​ Storage.set("newsFeedOfflineModelData", JSON.stringify(newsEntries));
73​ Storage.set("newsFeedLastFetchDate", JSON.stringify(new Date()));
74​ }
75​
76​ spacing: 10
77​
78​ onLoadingChanged: {
79​ if (newsFeedSyncModel.status == XmlListModel.Ready) {
80​ root.positionViewAtBeginning()
81​
82​ saveToCache()
83​ loadFromCache()
84​ }
85​ }
86​
87​ // Note: this model is *not* attached to the the view -- it's merely used for fetching the RSS feed
88​ XmlListModel {
89​ id: newsFeedSyncModel
90​
91​ property bool active: false
92​
93​ source: active ? feedUrl : ""
94​ query: "/rss/channel/item"
95​
96​ XmlRole { name: "title"; query: "title/string()" }
97​ XmlRole { name: "link"; query: "link/string()" }
98​ XmlRole { name: "pubDate"; query: "pubDate/string()" }
99​ }
100​
101​ model: ListModel {
102​ id: newsFeedOfflineModel
103​ }
104​
105​ delegate: Column {
106​ id: feedDelegate
107​
108​ readonly property date publicationDate: parsePubDate(model.pubDate)
109​ readonly property int ageInMinutes: minutesSince(publicationDate)
110​ readonly property bool isNew: ageInMinutes != -1 && ageInMinutes < maxHighlightedNewsAge
111​ readonly property string dateString: isNaN(publicationDate.getDate()) ? model.pubDate : publicationDate.toLocaleDateString()
112​
113​ x: 10
114​ width: parent.width - 2*x
115​
116​ Link {
117​ width: parent.width
118​
119​ text: model.title
120​
121​ onClicked: Qt.openUrlExternally(model.link)
122​ }
123​
124​ Label {
125​ width: parent.width
126​
127​ font.bold: isNew
128​ font.pointSize: 8
129​ color: disabledPalette.windowText
130​
131​ text: isNew ? i18nc("Example: Tue, 03 Jan 2017 10:00:00 (new)", "%1 (new)", dateString) : dateString
132​ }
133​ }
134​
135​ BusyIndicator {
136​ id: busyIndicator
137​
138​ height: newsHeading.height
139​
140​ running: newsFeed.loading
141​ }
142​
143​ Label {
144​ id: placeHolderLabel
145​
146​ x: 10
147​ width: parent.width - 2*x
148​
149​ text: i18n("No news entries available")
150​ color: disabledPalette.windowText
151​ visible: root.count === 0 && !root.loading
152​
153​ Behavior on opacity { NumberAnimation {} }
154​ }
155​
156​ SystemPalette {
157​ id: disabledPalette
158​ colorGroup: SystemPalette.Disabled
159​ }
160​
161​ function fetchFeed() {
162​ console.log("Fetching news feed")
163​
164​ newsFeedSyncModel.active = true
165​ newsFeedSyncModel.reload()
166​ }
167​
168​ Timer {
169​ id: delayedStartupTimer
170​
171​ // delay loading a bit so it has no effect on the KDevelop startup
172​ interval: 3000
173​ running: true
174​
175​ onTriggered: {
176​ loadFromCache()
177​
178​ // only fetch feed if items are out of date
179​ var lastFetchDate = new Date(JSON.parse(Storage.get("newsFeedLastFetchDate", null)));
180​ if (minutesSince(lastFetchDate) > root.updateInterval) {
181​ console.log("Last fetch of news feed was on " + lastFetchDate + ", updating now");
182​ root.fetchFeed();
183​ }
184​ }
185​ }
186​
187​ Timer {
188​ id: reloadFeedTimer
189​
190​ interval: root.updateInterval // 24 hours
191​ running: true
192​ repeat: true
193​
194​ onTriggered: root.fetchFeed()
195​ }
196​}