Differential D28922 Diff 82089 faces/UsedSensorsView.qml

Changeset View

Standalone View

View Options

faces/UsedSensorsView.qml

  • This file was added.
1​/*
2​ * Copyright 2019 Marco Martin <mart@kde.org>
3​ * Copyright 2019 David Edmundson <davidedmundson@kde.org>
4​ * Copyright 2019 Arjen Hiemstra <ahiemstra@heimr.nl>
5​ *
6​ * This program is free software; you can redistribute it and/or modify
7​ * it under the terms of the GNU Library General Public License as
8​ * published by the Free Software Foundation; either version 2, or
9​ * (at your option) any later version.
10​ *
11​ * This program is distributed in the hope that it will be useful,
12​ * but WITHOUT ANY WARRANTY; without even the implied warranty of
13​ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14​ * GNU General Public License for more details
15​ *
16​ * You should have received a copy of the GNU Library General Public
17​ * License along with this program; if not, write to the
18​ * Free Software Foundation, Inc.,
19​ * 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.
20​ */
21​
22​import QtQuick 2.9
23​import QtQuick.Layouts 1.2
24​import QtQuick.Controls 2.2 as QQC2
25​import QtQml.Models 2.12
ngrahamUnsubmitted
Done

as QQC2

ngraham: `as QQC2`
26​
27​import org.kde.kirigami 2.5 as Kirigami
28​import org.kde.kquickcontrols 2.0
29​
30​import org.kde.ksysguard.sensors 1.0 as Sensors
31​
32​DropArea {
33​ id: root
34​ Layout.fillWidth: true
35​ Layout.fillHeight: true
36​ Layout.preferredWidth: usedSensorsScroll.implicitWidth
37​
38​ property alias count: usedSensorsView.count
39​ property alias delegateComponent: delegateComponent
40​ property var sensorIds: []
41​ property var sensorColors: []
42​ property bool showColor: true
43​
44​ function appendSensor(sensorId) {
45​ insertSensor(usedSensorsModel.count, sensorId);
46​ }
47​
48​ function insertSensor(index, sensorId) {
49​ var color = Kirigami.Theme.highlightColor;
50​ color.hsvHue = Math.random();
51​ usedSensorsModel.insert(index, {"sensorId": sensorId, "color": color.toString()})
52​ usedSensorsModel.save()
53​ }
54​
55​ function positionViewAtIndex(index, mode) {
56​ usedSensorsView.positionViewAtIndex(index, mode);
57​ }
58​
59​ function load() {
60​ usedSensorsModel.clear();
61​ for (var i in sensorIds) {
62​ usedSensorsModel.append({"sensorId": sensorIds[i], "color": (sensorColors[i] || "").toString()})
63​ }
64​ }
65​
66​ Component {
67​ id: delegateComponent
68​ Kirigami.SwipeListItem {
69​ id: listItem
70​ actions: Kirigami.Action {
71​ icon.name: "list-remove"
72​ text: i18n("Remove")
73​ onTriggered: {
74​ usedSensorsModel.remove(index, 1);
75​ usedSensorsModel.save();
76​ }
77​ }
78​ contentItem: RowLayout {
79​ Kirigami.ListItemDragHandle {
80​ listItem: listItem
81​ listView: usedSensorsView
82​ onMoveRequested: {
83​ usedSensorsModel.move(oldIndex, newIndex, 1)
84​ usedSensorsModel.save();
85​ }
86​ }
87​ ColorButton {
88​ id: textColorButton
89​ color: model.color
90​ visible: root.showColor
91​ showAlphaChannel: true
92​ onAccepted: {
93​ usedSensorsModel.setProperty(index, "color", color.toString());
94​ usedSensorsModel.save();
95​ }
96​ }
97​ QQC2.Label {
98​ Layout.fillWidth: true
99​ text: sensor.name
100​ Sensors.Sensor {
101​ id: sensor
102​ sensorId: model.sensorId
103​ }
104​ }
105​ }
106​ }
107​ }
108​
109​ onEntered: {
110​ if (drag.formats.indexOf("application/x-ksysguard") == -1) {
111​ drag.accepted = false;
112​ return;
113​ }
114​ }
115​ function dropIndex() {
116​ if (!containsDrag) {
117​ return -1;
118​ } else if (usedSensorsView.count == 0) {
119​ return 0;
120​ }
121​
122​ var itemHeight = usedSensorsView.contentItem.children[0].height;
123​ var contentY = usedSensorsView.contentY + drag.y;
124​
125​ return Math.max(0, Math.min(usedSensorsView.count, Math.round(contentY / itemHeight)));
126​ }
127​
128​ onDropped: insertSensor(dropIndex(), drop.getDataAsString("application/x-ksysguard"))
129​
130​ QQC2.Label {
131​ anchors.centerIn: parent
132​ z: 2
133​ visible: usedSensorsView.count == 0
134​ text: i18n("Drop Sensors Here")
135​ }
136​ Rectangle {
137​ anchors {
138​ left: parent.left
139​ right: parent.right
140​ }
141​ height: Kirigami.Units.smallSpacing
142​ color: Kirigami.Theme.highlightColor
143​ visible: parent.containsDrag
144​ y: {
145​ if (usedSensorsView.count == 0) {
146​ return 0;
147​ }
148​ var itemHeight = usedSensorsView.contentItem.children[0].height;
149​ return itemHeight * parent.dropIndex() - usedSensorsView.contentY;
150​ }
151​ opacity: 0.6
152​ z: 2
153​ }
154​ QQC2.ScrollView {
155​ id: usedSensorsScroll
156​ anchors.fill: parent
157​
158​ ListView {
159​ id: usedSensorsView
160​
161​ model: ListModel {
162​ id: usedSensorsModel
163​ function save() {
164​ var ids = [];
165​ var colors = [];
166​ for (var i = 0; i < count; ++i) {
167​ ids.push(get(i).sensorId);
168​ colors.push(get(i).color);
169​ }
170​ root.sensorIds = ids;
171​ root.sensorColors = colors;
172​ }
173​ }
174​ //NOTE: this row is necessary to make the drag handle work
175​ delegate: Kirigami.DelegateRecycler {
176​ width: usedSensorsView.width
177​ sourceComponent: delegateComponent
178​ }
179​ }
180​ Component.onCompleted: background.visible = true;
181​ QQC2.ScrollBar.horizontal.visible: false
182​ }
183​}
184​