Differential D23789 Diff 67653 tests/ECMGenerateExportHeaderTest/consumer/testAPI_DISABLE_DEPRECATED_BEFORE_AND_AT.cmake

Changeset View

Standalone View

View Options

tests/ECMGenerateExportHeaderTest/consumer/testAPI_DISABLE_DEPRECATED_BEFORE_AND_AT.cmake

  • This file was added.
1​function(generate_hex_number _var_name _version)
2​ set(_hexnumber 0)
3​
4​ set(version_regex "^([0-9]+)\\.([0-9]+)\\.([0-9]+)$")
5​ string(REGEX REPLACE ${version_regex} "\\1" _version_major "${_version}")
6​ string(REGEX REPLACE ${version_regex} "\\2" _version_minor "${_version}")
7​ string(REGEX REPLACE ${version_regex} "\\3" _version_patch "${_version}")
8​ set(_outputformat)
9​ if (NOT CMAKE_VERSION VERSION_LESS 3.13)
10​ set(_outputformat OUTPUT_FORMAT HEXADECIMAL)
11​ endif()
12​ math(EXPR _hexnumber "${_version_major}*65536 + ${_version_minor}*256 + ${_version_patch}" ${_outputformat})
13​ set(${_var_name} ${_hexnumber} PARENT_SCOPE)
14​endfunction()
15​
16​
17​generate_hex_number(disable_deprecated_before_and_at_hexnumber ${LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT})
18​
19​if(GROUP_MODE STREQUAL "GROUP_USE_GROUP")
20​ set(_deprecation_macros_base_name "LIBGROUP")
21​else()
22​ set(_deprecation_macros_base_name "LIBRARY")
23​endif()
24​
25​function(testAPI code_var_name)
26​ set(options BUILD_TIME_ONLY_DISABLABLE NO_WARNING)
27​ set(oneValueArgs DEPRECATED_AT)
28​ set(multiValueArgs)
29​ cmake_parse_arguments(ARGS "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
30​
31​ if((NOT ARGS_DEPRECATED_AT) OR
32​ (ARGS_BUILD_TIME_ONLY_DISABLABLE AND ARGS_DEPRECATED_AT VERSION_GREATER DEPRECATED_EXCLUDED_BEFORE_AND_AT) OR
33​ (ARGS_DEPRECATED_AT VERSION_GREATER LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT))
34​ set(_build_result_expected TRUE)
35​ else()
36​ set(_build_result_expected FALSE)
37​ endif()
38​
39​ set(CMAKE_REQUIRED_LIBRARIES library)
40​ set(CMAKE_REQUIRED_DEFINITIONS "-D${_deprecation_macros_base_name}_DISABLE_DEPRECATED_BEFORE_AND_AT=${disable_deprecated_before_and_at_hexnumber}")
41​
42​ set(_code "
43​#include <library.hpp>
44​int main(int, char**)
45​{
46​ ${${code_var_name}}
47​}
48​")
49​
50​ unset(_result CACHE) # clear out as check_cxx_source_compiles caches the result
51​ check_cxx_source_compiles("${_code}" _result)
52​
53​ assert_var_bool_value(_result ${_build_result_expected})
54​
55​ # check warning
56​ if(_build_result_expected)
57​ if((ARGS_BUILD_TIME_ONLY_DISABLABLE AND NOT ARGS_NO_WARNING) OR
58​ (NOT ARGS_BUILD_TIME_ONLY_DISABLABLE AND ARGS_DEPRECATED_AT AND
59​ ARGS_DEPRECATED_AT VERSION_GREATER LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT))
60​ set(_dep_warning_result_expected FALSE)
61​ else()
62​ set(_dep_warning_result_expected TRUE)
63​ endif()
64​
65​ set(CMAKE_REQUIRED_FLAGS "-Werror=deprecated-declarations")
66​ set(CMAKE_REQUIRED_DEFINITIONS) # unset LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT, as LIBRARY_DEPRECATED_WARNINGS_SINCE defaults to it
67​ unset(_dep_warning_result CACHE) # clear out as check_cxx_source_compiles caches the result
68​ check_cxx_source_compiles("${_code}" _dep_warning_result)
69​ assert_var_bool_value(_dep_warning_result ${_dep_warning_result_expected})
70​ endif()
71​endfunction()