Differential D23789 Diff 67220 tests/ECMGenerateExportHeaderTest/consumer/CMakeLists.txt

Changeset View

Standalone View

View Options

tests/ECMGenerateExportHeaderTest/consumer/CMakeLists.txt

  • This file was added.
1​cmake_minimum_required(VERSION 3.0.0)
2​
3​project(consumer)
4​
5​include(CheckCXXSourceCompiles)
6​include(CMakeParseArguments)
7​
8​include(../../test_helpers.cmake)
9​
10​include("${CMAKE_CURRENT_BINARY_DIR}/../installation/${LIBRARY}/lib/library/LibraryTargets.cmake")
11​
12​# map any "CURRENT" value to library version string
13​# keep version in sync with the one used in library/CMakeLists.txt
14​set(library_version 2.40.0)
15​if(LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT STREQUAL "CURRENT")
16​ set(LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT ${library_version})
17​endif()
18​if(DEPRECATED_EXCLUDED_BEFORE_AND_AT STREQUAL "CURRENT")
19​ set(DEPRECATED_EXCLUDED_BEFORE_AND_AT ${library_version})
20​endif()
21​
22​
23​function(generate_hex_number _var_name _version)
24​ set(_hexnumber 0)
25​
26​ set(version_regex "^([0-9]+)\\.([0-9]+)\\.([0-9]+)$")
27​ string(REGEX REPLACE ${version_regex} "\\1" _version_major "${_version}")
28​ string(REGEX REPLACE ${version_regex} "\\2" _version_minor "${_version}")
29​ string(REGEX REPLACE ${version_regex} "\\3" _version_patch "${_version}")
30​ set(_outputformat)
31​ if (NOT CMAKE_VERSION VERSION_LESS 3.13)
32​ set(_outputformat OUTPUT_FORMAT HEXADECIMAL)
33​ endif()
34​ math(EXPR _hexnumber "${_version_major}*65536 + ${_version_minor}*256 + ${_version_patch}" ${_outputformat})
35​ set(${_var_name} ${_hexnumber} PARENT_SCOPE)
36​endfunction()
37​
38​
39​generate_hex_number(disable_deprecated_before_and_at_hexnumber ${LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT})
40​
41​function(testAPI code_var_name)
42​ set(options BUILD_TIME_ONLY_DISABLABLE NO_WARNING)
43​ set(oneValueArgs DEPRECATED_AT)
44​ set(multiValueArgs)
45​ cmake_parse_arguments(ARGS "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
46​
47​ if((NOT ARGS_DEPRECATED_AT) OR
48​ (ARGS_BUILD_TIME_ONLY_DISABLABLE AND ARGS_DEPRECATED_AT VERSION_GREATER DEPRECATED_EXCLUDED_BEFORE_AND_AT) OR
49​ (ARGS_DEPRECATED_AT VERSION_GREATER LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT))
50​ set(_build_result_expected TRUE)
51​ else()
52​ set(_build_result_expected FALSE)
53​ endif()
54​
55​ set(CMAKE_REQUIRED_LIBRARIES library)
56​ set(CMAKE_REQUIRED_DEFINITIONS "-DLIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT=${disable_deprecated_before_and_at_hexnumber}")
57​
58​ set(_code "
59​#include <library.hpp>
60​int main(int, char**)
61​{
62​ ${${code_var_name}}
63​}
64​")
65​
66​ unset(_result CACHE) # clear out as check_cxx_source_compiles caches the result
67​ check_cxx_source_compiles("${_code}" _result)
68​
69​ assert_var_bool_value(_result ${_build_result_expected})
70​
71​ # check warning
72​ if(_build_result_expected)
73​ if((ARGS_BUILD_TIME_ONLY_DISABLABLE AND NOT ARGS_NO_WARNING) OR
74​ (NOT ARGS_BUILD_TIME_ONLY_DISABLABLE AND ARGS_DEPRECATED_AT AND
75​ ARGS_DEPRECATED_AT VERSION_GREATER LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT))
76​ set(_dep_warning_result_expected FALSE)
77​ else()
78​ set(_dep_warning_result_expected TRUE)
79​ endif()
80​
81​ set(CMAKE_REQUIRED_FLAGS "-Werror=deprecated-declarations")
82​ set(CMAKE_REQUIRED_DEFINITIONS) # unset LIBRARY_DISABLE_DEPRECATED_BEFORE_AND_AT, as LIBRARY_DEPRECATED_WARNINGS_SINCE defaults to it
83​ unset(_dep_warning_result CACHE) # clear out as check_cxx_source_compiles caches the result
84​ check_cxx_source_compiles("${_code}" _dep_warning_result)
85​ assert_var_bool_value(_dep_warning_result ${_dep_warning_result_expected})
86​ endif()
87​endfunction()
88​
89​
90​# for each API element test their visibility to the compiler and if a warning is emitted
91​set(_code "Enum enumerator = Enumerator_deprecatedAt2_0;")
92​testAPI(_code DEPRECATED_AT 2.0 BUILD_TIME_ONLY_DISABLABLE NO_WARNING)
93​
94​set(_code "Enum enumerator = Enumerator_not_deprecated;")
95​testAPI(_code)
96​
97​set(_code "function_deprecatedAt2_0();")
98​testAPI(_code DEPRECATED_AT 2.0)
99​
100​set(_code "function_deprecatedAt2_12();")
101​testAPI(_code DEPRECATED_AT 2.12)
102​
103​set(_code "function_not_deprecated();")
104​testAPI(_code)
105​
106​set(_code "Class().method_deprecatedAt2_0();")
107​testAPI(_code DEPRECATED_AT 2.0 BUILD_TIME_ONLY_DISABLABLE)
108​
109​set(_code "Class().method_deprecatedAt2_12();")
110​testAPI(_code DEPRECATED_AT 2.12 BUILD_TIME_ONLY_DISABLABLE)
111​
112​set(_code "Class().method_not_deprecated();")
113​testAPI(_code)
114​
115​add_executable(dummy main.cpp)