Differential D21721 Diff 64855 src/qtquick/qml/Page.qml

Changeset View

Standalone View

View Options

src/qtquick/qml/Page.qml

  • This file was added.
1​/*
2​ * Copyright (C) 2019 Dan Leinir Turthra Jensen <admin@leinir.dk>
3​ *
4​ * This library is free software; you can redistribute it and/or
5​ * modify it under the terms of the GNU Lesser General Public
6​ * License as published by the Free Software Foundation; either
7​ * version 2.1 of the License, or (at your option) version 3, or any
8​ * later version accepted by the membership of KDE e.V. (or its
9​ * successor approved by the membership of KDE e.V.), which shall
10​ * act as a proxy defined in Section 6 of version 3 of the license.
11​ *
12​ * This library is distributed in the hope that it will be useful,
13​ * but WITHOUT ANY WARRANTY; without even the implied warranty of
14​ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15​ * Lesser General Public License for more details.
16​ *
17​ * You should have received a copy of the GNU Lesser General Public
18​ * License along with this library. If not, see <http://www.gnu.org/licenses/>.
19​ *
20​ */
21​
22​/**
23​ * @brief A Kirigami.Page component used for managing KNS entries
24​ *
25​ * This component is functionally equivalent to the old DownloadDialog
26​ * @see KNewStuff::DownloadDialog
27​ */
28​
29​import QtQuick 2.11
30​import QtQuick.Controls 2.11 as QtControls
31​import QtQuick.Layouts 1.11 as QtLayouts
32​import QtGraphicalEffects 1.11 as QtEffects
33​
34​import org.kde.kcm 1.2 as KCM
35​import org.kde.kirigami 2.7 as Kirigami
36​
37​import org.kde.newstuff 1.1 as NewStuff
38​
39​import "private" as Private
40​import "private/entrygriddelegates" as EntryGridDelegates
41​
42​KCM.GridViewKCM {
43​ id: root;
44​ /**
45​ * @brief The configuration file which describes the application (knsrc)
46​ *
47​ * The format and location of this file is found in the documentation for
48​ * KNS3::DownloadDialog
49​ */
50​ property alias configFile: newStuffEngine.configFile;
51​ readonly property alias engine: newStuffEngine;
52​
53​ /**
54​ * Any generic message from the NewStuff.Engine
55​ * @param message The message to be shown to the user
56​ */
57​ signal message(string message);
58​ /**
59​ * A message posted usually describing that whatever action a recent busy
60​ * message said was happening has been completed
61​ * @param message The message to be shown to the user
62​ */
63​ signal idleMessage(string message);
64​ /**
65​ * A message posted when the engine is busy doing something long duration
66​ * (usually this will be when fetching installation data)
67​ * @param message The message to be shown to the user
68​ */
69​ signal busyMessage(string message);
70​ /**
71​ * A message posted when something has gone wrong
72​ * @param message The message to be shown to the user
73​ */
74​ signal errorMessage(string message);
75​
76​ property string uninstallLabel: i18nc("Request uninstallation of this item", "Uninstall");
77​ property string useLabel: i18nc("If a knsrc file defines an adoption command, the option to run this command and 'use' an item becomes available. This is the text for an action to do so.", "Use");
78​
79​ property int viewMode: Page.ViewMode.Tiles
80​ enum ViewMode {
81​ Tiles,
82​ Icons,
83​ Preview
84​ }
85​
86​ title: newStuffEngine.name
87​ NewStuff.Engine {
88​ id: newStuffEngine;
89​ onMessage: root.message(message);
90​ onIdleMessage: root.idleMessage(message);
91​ onBusyMessage: root.busyMessage(message);
92​ onErrorMessage: root.errorMessage(message);
93​ }
94​ NewStuff.QuestionAsker {}
95​
96​ titleDelegate: QtLayouts.RowLayout {
97​ Kirigami.Heading {
98​ id: title
99​ level: 1
100​
101​ QtLayouts.Layout.fillWidth: true;
102​ QtLayouts.Layout.preferredWidth: titleTextMetrics.width
103​ QtLayouts.Layout.minimumWidth: titleTextMetrics.width
104​ opacity: root.isCurrentPage ? 1 : 0.4
105​ maximumLineCount: 1
106​ elide: Text.ElideRight
107​ text: root.title
108​ TextMetrics {
109​ id: titleTextMetrics
110​ text: root.title
111​ font: title.font
112​ }
113​ }
114​ QtControls.ButtonGroup {
115​ id: displayModeGroup
116​ buttons: [displayModeTiles, displayModeIcons]
117​ }
118​ QtControls.ToolButton {
119​ id: displayModeTiles
120​ icon.name: "view-list-details"
121​ onClicked: { root.viewMode = Page.ViewMode.Tiles; }
122​ checked: root.viewMode == Page.ViewMode.Tiles
123​ }
124​ QtControls.ToolButton {
125​ id: displayModeIcons
126​ icon.name: "view-list-icons"
127​ onClicked: { root.viewMode = Page.ViewMode.Icons; }
128​ checked: root.viewMode == Page.ViewMode.Icons
129​ }
130​ QtControls.ToolButton {
131​ id: displayPreview
132​ icon.name: "view-preview"
133​ onClicked: { root.viewMode = Page.ViewMode.Preview; }
134​ checked: root.viewMode == Page.ViewMode.Preview
135​ }
136​ Kirigami.ActionTextField {
137​ id: searchField
138​ placeholderText: i18n("Search...")
139​ focusSequence: "Ctrl+F"
140​ rightActions: [
141​ Kirigami.Action {
142​ iconName: "edit-clear"
143​ visible: searchField.text !== ""
144​ onTriggered: {
145​ searchField.text = "";
146​ searchField.accepted();
147​ }
148​ }
149​ ]
150​ onAccepted: {
151​ newStuffEngine.searchTerm = searchField.text;
152​ }
153​ }
154​ }
155​
156​ footer: QtLayouts.RowLayout {
157​ QtControls.ComboBox {
158​ id: categoriesCombo
159​ QtLayouts.Layout.fillWidth: true
160​ model: newStuffEngine.categories
161​ textRole: "displayName"
162​ onCurrentIndexChanged: {
163​ newStuffEngine.categoriesFilter = model.data(currentIndex, NewStuff.CategoriesModel.NameRole);
164​ }
165​ }
166​ QtControls.ComboBox {
167​ id: filterCombo
168​ QtLayouts.Layout.fillWidth: true
169​ model: ListModel {}
170​ Component.onCompleted: {
171​ filterCombo.model.append({ text: i18nc("List option which will set the filter to show everything", "Show Everything") });
172​ filterCombo.model.append({ text: i18nc("List option which will set the filter so only installed items are shown", "Installed Only") });
173​ filterCombo.model.append({ text: i18nc("List option which will set the filter so only installed items with updates available are shown", "Updateable Only") });
174​ filterCombo.currentIndex = newStuffEngine.filter;
175​ }
176​ onCurrentIndexChanged: {
177​ newStuffEngine.filter = currentIndex;
178​ }
179​ }
180​ QtControls.ComboBox {
181​ id: sortCombo
182​ QtLayouts.Layout.fillWidth: true
183​ model: ListModel { }
184​ Component.onCompleted: {
185​ sortCombo.model.append({ text: i18nc("List option which will set the sort order to based on when items were most recently updated", "Show most recent first") });
186​ sortCombo.model.append({ text: i18nc("List option which will set the sort order to be alphabetical based on the name", "Sort alphabetically") });
187​ sortCombo.model.append({ text: i18nc("List option which will set the sort order to based on user ratings", "Show highest rated first") });
188​ sortCombo.model.append({ text: i18nc("List option which will set the sort order to based on number of downloads", "Show most downloaded first") });
189​ sortCombo.currentIndex = newStuffEngine.sortOrder;
190​ }
191​ onCurrentIndexChanged: {
192​ newStuffEngine.sortOrder = currentIndex;
193​ }
194​ }
195​ }
196​
197​ view.model: NewStuff.ItemsModel {
198​ id: newStuffModel;
199​ engine: newStuffEngine;
200​ }
201​ NewStuff.DownloadItemsSheet {
202​ id: downloadItemsSheet
203​ onItemPicked: {
204​ var entryName = newStuffModel.data(entryId, NewStuff.ItemsModel.NameRole);
205​ applicationWindow().showPassiveNotification(i18nc("A passive notification shown when installation of an item is initiated", "Installing %1 from %2").arg(downloadName).arg(entryName), 1500);
206​ newStuffModel.installItem(entryId, downloadItemId);
207​ }
208​ }
209​
210​ view.implicitCellWidth: root.viewMode == Page.ViewMode.Tiles ? Kirigami.Units.gridUnit * 30 : (root.viewMode == Page.ViewMode.Preview ? Kirigami.Units.gridUnit * 25 : Kirigami.Units.gridUnit * 10)
211​ view.implicitCellHeight: root.viewMode == Page.ViewMode.Tiles ? Math.round(view.implicitCellWidth / 3) : (root.viewMode == Page.ViewMode.Preview ? Kirigami.Units.gridUnit * 25 : Math.round(view.implicitCellWidth / 1.6) + Kirigami.Units.gridUnit*2)
ahiemstraUnsubmitted
Done

For readability, it would be better to move these to their own files.

ahiemstra: For readability, it would be better to move these to their own files.
leinirAuthorUnsubmitted
Done

It would, yes... Feared it was a bit clugey, but it was super straightforward, so yay for that ;)

leinir: It would, yes... Feared it was a bit clugey, but it was super straightforward, so yay for that…
212​ view.delegate: root.viewMode == Page.ViewMode.Tiles ? tileDelegate : (root.viewMode == Page.ViewMode.Preview ? bigPreviewDelegate : thumbDelegate)
213​
214​ Component {
215​ id: bigPreviewDelegate
216​ EntryGridDelegates.BigPreviewDelegate { }
217​ }
218​ Component {
219​ id: tileDelegate
220​ EntryGridDelegates.TileDelegate {
221​ useLabel: root.useLabel
222​ uninstallLabel: root.uninstallLabel
223​ }
224​ }
225​ Component {
226​ id: thumbDelegate
227​ EntryGridDelegates.ThumbDelegate {
228​ useLabel: root.useLabel
229​ uninstallLabel: root.uninstallLabel
230​ }
231​ }
232​
233​ Component {
234​ id: detailsPage;
235​ NewStuff.EntryDetails { }
236​ }
237​}