Differential D21721 Diff 64426 src/qtquick/qml/Page.qml

Changeset View

Standalone View

View Options

src/qtquick/qml/Page.qml

  • This file was added.
1​/*
2​ * Copyright (C) 2019 Dan Leinir Turthra Jensen <admin@leinir.dk>
3​ *
4​ * This library is free software; you can redistribute it and/or
5​ * modify it under the terms of the GNU Lesser General Public
6​ * License as published by the Free Software Foundation; either
7​ * version 2.1 of the License, or (at your option) version 3, or any
8​ * later version accepted by the membership of KDE e.V. (or its
9​ * successor approved by the membership of KDE e.V.), which shall
10​ * act as a proxy defined in Section 6 of version 3 of the license.
11​ *
12​ * This library is distributed in the hope that it will be useful,
13​ * but WITHOUT ANY WARRANTY; without even the implied warranty of
14​ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15​ * Lesser General Public License for more details.
16​ *
17​ * You should have received a copy of the GNU Lesser General Public
18​ * License along with this library. If not, see <http://www.gnu.org/licenses/>.
19​ *
20​ */
21​
22​/**
23​ * @brief A Kirigami.Page component used for managing KNS entries
24​ *
25​ * This component is functionally equivalent to the old DownloadDialog
26​ * @see KNewStuff::DownloadDialog
27​ */
28​
29​import QtQuick 2.7
30​import QtQuick.Controls 2.5 as QtControls
31​import QtQuick.Layouts 1.12 as QtLayouts
32​import QtGraphicalEffects 1.12 as QtEffects
33​import org.kde.kcm 1.2 as KCM
34​import org.kde.kirigami 2.7 as Kirigami
35​import org.kde.newstuff 1.1 as NewStuff
36​import "private" as Private
37​
38​KCM.GridViewKCM {
39​ id: root;
40​ /**
41​ * @brief The configuration file which describes the application (knsrc)
42​ *
43​ * The format and location of this file is found in the documentation for
44​ * KNS3::DownloadDialog
45​ */
46​ property alias configFile: newStuffEngine.configFile;
47​ readonly property alias engine: newStuffEngine;
48​
49​ /**
50​ * Any generic message from the NewStuff.Engine
51​ * @param message The message to be shown to the user
52​ */
53​ signal message(string message);
54​ /**
55​ * A message posted usually describing that whatever action a recent busy
56​ * message said was happening has been completed
57​ * @param message The message to be shown to the user
58​ */
59​ signal idleMessage(string message);
60​ /**
61​ * A message posted when the engine is busy doing something long duration
62​ * (usually this will be when fetching installation data)
63​ * @param message The message to be shown to the user
64​ */
65​ signal busyMessage(string message);
66​ /**
67​ * A message posted when something has gone wrong
68​ * @param message The message to be shown to the user
69​ */
70​ signal errorMessage(string message);
71​
72​ property string uninstallLabel: i18nc("Request uninstallation of this item", "Uninstall");
73​ property string useLabel: i18nc("If a knsrc file defines an adoption command, the option to run this command and 'use' an item becomes available. This is the text for an action to do so.", "Use");
74​
75​ property int viewMode: Page.ViewMode.Tiles
76​ enum ViewMode {
77​ Tiles,
78​ Icons,
79​ Preview
80​ }
81​
82​ title: newStuffEngine.name
83​ NewStuff.Engine {
84​ id: newStuffEngine;
85​ onMessage: root.message(message);
86​ onIdleMessage: root.idleMessage(message);
87​ onBusyMessage: root.busyMessage(message);
88​ onErrorMessage: root.errorMessage(message);
89​ }
90​ NewStuff.QuestionAsker {}
91​
92​ titleDelegate: QtLayouts.RowLayout {
93​ Kirigami.Heading {
94​ id: title
95​ level: 1
96​
97​ QtLayouts.Layout.fillWidth: true;
98​ QtLayouts.Layout.preferredWidth: titleTextMetrics.width
99​ QtLayouts.Layout.minimumWidth: titleTextMetrics.width
100​ opacity: root.isCurrentPage ? 1 : 0.4
101​ maximumLineCount: 1
102​ elide: Text.ElideRight
103​ text: root.title
104​ TextMetrics {
105​ id: titleTextMetrics
106​ text: root.title
107​ font: title.font
108​ }
109​ }
110​ QtControls.ButtonGroup {
111​ id: displayModeGroup
112​ buttons: [displayModeTiles, displayModeIcons]
113​ }
114​ QtControls.ToolButton {
115​ id: displayModeTiles
116​ icon.name: "view-list-details"
117​ onClicked: { root.viewMode = Page.ViewMode.Tiles; }
118​ checked: root.viewMode == Page.ViewMode.Tiles
119​ }
120​ QtControls.ToolButton {
121​ id: displayModeIcons
122​ icon.name: "view-list-icons"
123​ onClicked: { root.viewMode = Page.ViewMode.Icons; }
124​ checked: root.viewMode == Page.ViewMode.Icons
125​ }
126​ QtControls.ToolButton {
127​ id: displayPreview
128​ icon.name: "view-preview"
129​ onClicked: { root.viewMode = Page.ViewMode.Preview; }
130​ checked: root.viewMode == Page.ViewMode.Preview
131​ }
132​ Kirigami.ActionTextField {
133​ id: searchField
134​ placeholderText: i18n("Search...")
135​ focusSequence: "Ctrl+F"
136​ rightActions: [
137​ Kirigami.Action {
138​ iconName: "edit-clear"
139​ visible: searchField.text !== ""
140​ onTriggered: {
141​ searchField.text = "";
142​ searchField.accepted();
143​ }
144​ }
145​ ]
146​ onAccepted: {
147​ newStuffEngine.searchTerm = searchField.text;
148​ }
149​ }
150​ }
151​
152​ footer: QtLayouts.RowLayout {
153​ QtControls.ComboBox {
154​ id: categoriesCombo
155​ QtLayouts.Layout.fillWidth: true
156​ model: newStuffEngine.categories
157​ textRole: "displayName"
158​ onCurrentIndexChanged: {
159​ newStuffEngine.categoriesFilter = model.data(currentIndex, NewStuff.CategoriesModel.NameRole);
160​ }
161​ }
162​ QtControls.ComboBox {
163​ id: filterCombo
164​ QtLayouts.Layout.fillWidth: true
165​ model: ListModel {}
166​ Component.onCompleted: {
167​ filterCombo.model.append({ text: i18nc("List option which will set the filter to show everything", "Show Everything") });
168​ filterCombo.model.append({ text: i18nc("List option which will set the filter so only installed items are shown", "Installed Only") });
169​ filterCombo.model.append({ text: i18nc("List option which will set the filter so only installed items with updates available are shown", "Updateable Only") });
170​ filterCombo.currentIndex = newStuffEngine.filter;
171​ }
172​ onCurrentIndexChanged: {
173​ newStuffEngine.filter = currentIndex;
174​ }
175​ }
176​ QtControls.ComboBox {
177​ id: sortCombo
178​ QtLayouts.Layout.fillWidth: true
179​ model: ListModel { }
180​ Component.onCompleted: {
181​ sortCombo.model.append({ text: i18nc("List option which will set the sort order to based on when items were most recently updated", "Show most recent first") });
182​ sortCombo.model.append({ text: i18nc("List option which will set the sort order to be alphabetical based on the name", "Sort alphabetically") });
183​ sortCombo.model.append({ text: i18nc("List option which will set the sort order to based on user ratings", "Show highest rated first") });
184​ sortCombo.model.append({ text: i18nc("List option which will set the sort order to based on number of downloads", "Show most downloaded first") });
185​ sortCombo.currentIndex = newStuffEngine.sortOrder;
186​ }
187​ onCurrentIndexChanged: {
188​ newStuffEngine.sortOrder = currentIndex;
189​ }
190​ }
191​ }
192​
193​ view.model: NewStuff.ItemsModel {
194​ id: newStuffModel;
195​ engine: newStuffEngine;
196​ }
197​ NewStuff.DownloadItemsSheet {
198​ id: downloadItemsSheet
199​ onItemPicked: {
200​ var entryName = newStuffModel.data(entryId, NewStuff.ItemsModel.NameRole);
201​ applicationWindow().showPassiveNotification(i18nc("A passive notification shown when installation of an item is initiated", "Installing %1 from %2").arg(downloadName).arg(entryName), 1500);
202​ newStuffModel.installItem(entryId, downloadItemId);
203​ }
204​ }
205​
206​ view.implicitCellWidth: root.viewMode == Page.ViewMode.Tiles ? Kirigami.Units.gridUnit * 30 : (root.viewMode == Page.ViewMode.Preview ? Kirigami.Units.gridUnit * 25 : Kirigami.Units.gridUnit * 10)
207​ view.implicitCellHeight: root.viewMode == Page.ViewMode.Tiles ? Math.round(view.implicitCellWidth / 3) : (root.viewMode == Page.ViewMode.Preview ? Kirigami.Units.gridUnit * 25 : Math.round(view.implicitCellWidth / 1.6) + Kirigami.Units.gridUnit*2)
208​ view.delegate: root.viewMode == Page.ViewMode.Tiles ? tileDelegate : (root.viewMode == Page.ViewMode.Preview ? bigPreviewDelegate : thumbDelegate)
209​
210​ Component {
211​ id: bigPreviewDelegate
ahiemstraUnsubmitted
Done

For readability, it would be better to move these to their own files.

ahiemstra: For readability, it would be better to move these to their own files.
leinirAuthorUnsubmitted
Done

It would, yes... Feared it was a bit clugey, but it was super straightforward, so yay for that ;)

leinir: It would, yes... Feared it was a bit clugey, but it was super straightforward, so yay for that…
212​ Private.GridTileDelegate {
213​ id: bigPreviewDelegateRoot
214​ actionsAnchors.topMargin: bigPreview.height + Kirigami.Units.smallSpacing * 2
215​ function showDetails() {
216​ pageStack.push(detailsPage, {
217​ newStuffModel: root.view.model,
218​ index: model.index,
219​ name: model.name,
220​ author: model.author,
221​ previews: model.previews,
222​ shortSummary: model.shortSummary,
223​ summary: model.summary,
224​ homepage: model.homepage,
225​ donationLink: model.donationLink,
226​ status: model.status,
227​ commentsCount: model.numberOfComments,
228​ rating: model.rating,
229​ downloadCount: model.downloadCount,
230​ downloadLinks: model.downloadLinks,
231​ providerId: model.providerId
232​ });
233​ }
234​ actions: [
235​ Kirigami.Action {
236​ text: root.useLabel
237​ iconName: "dialog-ok-apply"
238​ onTriggered: { model.adopt(model.index); }
239​ enabled: (model.status == NewStuff.ItemsModel.InstalledStatus || model.status == NewStuff.ItemsModel.UpdateableStatus) && newStuffEngine.hasAdoptionCommand
240​ visible: enabled
241​ },
242​ Kirigami.Action {
243​ text: model.downloadCount == 1 ? i18nc("Request installation of this item, available when there is exactly one downloadable item", "Install") : i18nc("Show installation options, where there is more than one downloadable item", "Install...");
244​ iconName: "install"
245​ onTriggered: {
246​ if (model.downloadCount == 1) {
247​ newStuffModel.installItem(model.index, 1);
248​ } else {
249​ downloadItemsSheet.downloadLinks = model.downloadLinks;
250​ downloadItemsSheet.entryId = model.index;
251​ downloadItemsSheet.open();
252​ }
253​ }
254​ enabled: model.status == NewStuff.ItemsModel.DownloadableStatus || model.status == NewStuff.ItemsModel.DeletedStatus;
255​ visible: enabled;
256​ },
257​ Kirigami.Action {
258​ text: i18nc("Request updating of this item", "Update");
259​ iconName: "update"
260​ onTriggered: { newStuffModel.installItem(model.index); }
261​ enabled: model.status == NewStuff.ItemsModel.UpdateableStatus;
262​ visible: enabled;
263​ },
264​ Kirigami.Action {
265​ text: root.uninstallLabel
266​ iconName: "uninstall"
267​ onTriggered: { newStuffModel.uninstallItem(model.index); }
268​ enabled: model.status == NewStuff.ItemsModel.InstalledStatus
269​ visible: enabled;
270​ }
271​ ]
272​ thumbnailAvailable: model.previewsSmall.length > 0
273​ tile: Item {
274​ anchors {
275​ fill: parent
276​ margins: Kirigami.Units.smallSpacing
277​ }
278​ QtLayouts.ColumnLayout {
279​ anchors.fill: parent;
280​ Item {
281​ QtLayouts.Layout.fillWidth: true
282​ QtLayouts.Layout.minimumHeight: width / 1.8
283​ QtLayouts.Layout.maximumHeight: width / 1.8
284​ Image {
285​ id: bigPreview
286​ asynchronous: true;
287​ fillMode: Image.PreserveAspectCrop;
288​ source: thumbnailAvailable ? model.previews[0] : "";
289​ anchors.fill: parent
290​ }
291​ QtEffects.DropShadow {
292​ anchors.fill: bigPreview
293​ horizontalOffset: 0
294​ verticalOffset: 0
295​ radius: Kirigami.Units.largeSpacing
296​ samples: radius * 2
297​ color: "#80000000"
298​ source: bigPreview
299​ }
300​ Kirigami.Icon {
301​ id: updateAvailableBadge;
302​ opacity: (model.status == NewStuff.ItemsModel.UpdateableStatus) ? 1 : 0;
303​ Behavior on opacity { NumberAnimation { duration: Kirigami.Units.shortDuration; } }
304​ anchors {
305​ top: parent.top;
306​ left: parent.left;
307​ margins: -Kirigami.Units.smallSpacing;
308​ }
309​ height: Kirigami.Units.iconSizes.medium;
310​ width: height;
311​ source: "package-installed-outdated";
312​ }
313​ Kirigami.Icon {
314​ id: installedBadge;
315​ opacity: (model.status == NewStuff.ItemsModel.InstalledStatus) ? 1 : 0;
316​ Behavior on opacity { NumberAnimation { duration: Kirigami.Units.shortDuration; } }
317​ anchors {
318​ top: parent.top;
319​ left: parent.left;
320​ }
321​ height: Kirigami.Units.iconSizes.medium;
322​ width: height;
323​ source: "package-installed-updated";
324​ }
325​ Item {
326​ anchors {
327​ top: parent.top;
328​ right: parent.right;
329​ }
330​ height: Kirigami.Units.iconSizes.large;
331​ width: height;
332​ Kirigami.Icon {
333​ id: infoIcon
334​ source: "documentinfo"
335​ anchors.fill: parent
336​ }
337​ MouseArea {
338​ anchors.fill: parent
339​ onClicked: { bigPreviewDelegateRoot.showDetails(); }
340​ }
341​ QtEffects.Glow {
342​ anchors.fill: infoIcon
343​ radius: 1
344​ samples: 2
345​ spread: 0.3
346​ color: "white"
347​ source: infoIcon
348​ }
349​ }
350​ }
351​ Private.Rating {
352​ QtLayouts.Layout.fillWidth: true
353​ rating: model.rating / 10
354​ }
355​ Kirigami.Heading {
356​ QtLayouts.Layout.fillWidth: true
357​ level: 5
358​ elide: Text.ElideRight
359​ text: i18nc("The number of times the item has been downloaded", "%1 downloads").arg(model.downloadCount)
360​ }
361​ Kirigami.Heading {
362​ QtLayouts.Layout.fillWidth: true
363​ elide: Text.ElideRight
364​ level: 3
365​ text: model.name
366​ }
367​ Kirigami.Heading {
368​ QtLayouts.Layout.fillWidth: true
369​ elide: Text.ElideRight
370​ level: 4
371​ textFormat: Text.StyledText
372​ text: i18nc("Subheading for the tile view, located immediately underneath the name of the item", "By <i>%1</i>").arg(model.author.name)
373​ }
374​ QtControls.Label {
375​ QtLayouts.Layout.fillWidth: true
376​ QtLayouts.Layout.fillHeight: true
377​ wrapMode: Text.Wrap
378​ text: model.shortSummary.length > 0 ? model.shortSummary : model.summary
379​ elide: Text.ElideRight
380​ }
381​ }
382​ Item {
383​ anchors.fill: parent
384​ opacity: (model.status == NewStuff.ItemsModel.InstallingStatus || model.status == NewStuff.ItemsModel.UpdatingStatus) ? 1 : 0
385​ Behavior on opacity { NumberAnimation { duration: Kirigami.Units.longDuration; } }
386​ Rectangle {
387​ anchors.fill: parent
388​ color: Kirigami.Theme.backgroundColor
389​ opacity: 0.5;
390​ }
391​ QtControls.BusyIndicator {
392​ anchors.centerIn: parent
393​ running: parent.opacity > 0
394​ }
395​ }
396​ MouseArea {
397​ anchors.fill: parent;
398​ onClicked: bigPreviewDelegateRoot.showDetails();
399​ }
400​ }
401​ }
402​ }
403​ Component {
404​ id: tileDelegate
405​ Private.GridTileDelegate {
406​ id: tileDelegateRoot
407​ function showDetails() {
408​ pageStack.push(detailsPage, {
409​ newStuffModel: root.view.model,
410​ index: model.index,
411​ name: model.name,
412​ author: model.author,
413​ previews: model.previews,
414​ shortSummary: model.shortSummary,
415​ summary: model.summary,
416​ homepage: model.homepage,
417​ donationLink: model.donationLink,
418​ status: model.status,
419​ commentsCount: model.numberOfComments,
420​ rating: model.rating,
421​ downloadCount: model.downloadCount,
422​ downloadLinks: model.downloadLinks,
423​ providerId: model.providerId
424​ });
425​ }
426​ actions: [
427​ Kirigami.Action {
428​ text: root.useLabel
429​ iconName: "dialog-ok-apply"
430​ onTriggered: { model.adopt(model.index); }
431​ enabled: (model.status == NewStuff.ItemsModel.InstalledStatus || model.status == NewStuff.ItemsModel.UpdateableStatus) && newStuffEngine.hasAdoptionCommand
432​ visible: enabled
433​ },
434​ Kirigami.Action {
435​ text: model.downloadCount == 1 ? i18nc("Request installation of this item, available when there is exactly one downloadable item", "Install") : i18nc("Show installation options, where there is more than one downloadable item", "Install...");
436​ iconName: "install"
437​ onTriggered: {
438​ if (model.downloadCount == 1) {
439​ newStuffModel.installItem(model.index, 1);
440​ } else {
441​ downloadItemsSheet.downloadLinks = model.downloadLinks;
442​ downloadItemsSheet.entryId = model.index;
443​ downloadItemsSheet.open();
444​ }
445​ }
446​ enabled: model.status == NewStuff.ItemsModel.DownloadableStatus || model.status == NewStuff.ItemsModel.DeletedStatus;
447​ visible: enabled;
448​ },
449​ Kirigami.Action {
450​ text: i18nc("Request updating of this item", "Update");
451​ iconName: "update"
452​ onTriggered: { newStuffModel.installItem(model.index); }
453​ enabled: model.status == NewStuff.ItemsModel.UpdateableStatus;
454​ visible: enabled;
455​ },
456​ Kirigami.Action {
457​ text: root.uninstallLabel
458​ iconName: "uninstall"
459​ onTriggered: { newStuffModel.uninstallItem(model.index); }
460​ enabled: model.status == NewStuff.ItemsModel.InstalledStatus
461​ visible: enabled;
462​ },
463​ Kirigami.Action {
464​ text: i18nc("Show a page with details for this item", "Details...")
465​ iconName: "documentinfo"
466​ onTriggered: { tileDelegateRoot.showDetails(); }
467​ }
468​ ]
469​ thumbnailAvailable: model.previewsSmall.length > 0
470​ tile: Item {
471​ anchors {
472​ fill: parent
473​ margins: Kirigami.Units.smallSpacing
474​ }
475​ QtLayouts.GridLayout {
476​ anchors.fill: parent;
477​ columns: 2
478​ QtLayouts.ColumnLayout {
479​ QtLayouts.Layout.minimumWidth: view.implicitCellWidth / 5
480​ QtLayouts.Layout.maximumWidth: view.implicitCellWidth / 5
481​ Item {
482​ QtLayouts.Layout.fillWidth: true
483​ QtLayouts.Layout.minimumHeight: width
484​ QtLayouts.Layout.maximumHeight: width
485​ Image {
486​ id: tilePreview
487​ asynchronous: true;
488​ fillMode: Image.PreserveAspectFit;
489​ source: thumbnailAvailable ? model.previewsSmall[0] : "";
490​ anchors {
491​ fill: parent
492​ margins: Kirigami.Units.smallSpacing
493​ }
494​ verticalAlignment: Image.AlignTop
495​ }
496​ QtEffects.DropShadow {
497​ anchors.fill: tilePreview
498​ horizontalOffset: 0
499​ verticalOffset: 0
500​ radius: Kirigami.Units.largeSpacing
501​ samples: radius * 2
502​ color: "#80000000"
503​ source: tilePreview
504​ }
505​ Kirigami.Icon {
506​ id: updateAvailableBadge;
507​ opacity: (model.status == NewStuff.ItemsModel.UpdateableStatus) ? 1 : 0;
508​ Behavior on opacity { NumberAnimation { duration: Kirigami.Units.shortDuration; } }
509​ anchors {
510​ top: parent.top;
511​ left: parent.left;
512​ margins: -Kirigami.Units.smallSpacing;
513​ }
514​ height: Kirigami.Units.iconSizes.smallMedium;
515​ width: height;
516​ source: "package-installed-outdated";
517​ }
518​ Kirigami.Icon {
519​ id: installedBadge;
520​ opacity: (model.status == NewStuff.ItemsModel.InstalledStatus) ? 1 : 0;
521​ Behavior on opacity { NumberAnimation { duration: Kirigami.Units.shortDuration; } }
522​ anchors {
523​ top: parent.top;
524​ left: parent.left;
525​ margins: -Kirigami.Units.smallSpacing;
526​ }
527​ height: Kirigami.Units.iconSizes.smallMedium;
528​ width: height;
529​ source: "package-installed-updated";
530​ }
531​ }
532​ Item {
533​ QtLayouts.Layout.fillHeight: true
534​ }
535​ }
536​ QtLayouts.ColumnLayout {
537​ QtLayouts.Layout.fillWidth: true
538​ QtLayouts.Layout.fillHeight: true
539​ Kirigami.Heading {
540​ QtLayouts.Layout.fillWidth: true
541​ elide: Text.ElideRight
542​ level: 3
543​ text: model.name
544​ }
545​ Kirigami.Heading {
546​ QtLayouts.Layout.fillWidth: true
547​ elide: Text.ElideRight
548​ level: 4
549​ textFormat: Text.StyledText
550​ text: i18nc("Subheading for the tile view, located immediately underneath the name of the item", "By <i>%1</i>").arg(model.author.name)
551​ }
552​ QtControls.Label {
553​ QtLayouts.Layout.fillWidth: true
554​ QtLayouts.Layout.fillHeight: true
555​ wrapMode: Text.Wrap
556​ text: model.shortSummary.length > 0 ? model.shortSummary : model.summary
557​ elide: Text.ElideRight
558​ }
559​ }
560​ Private.Rating {
561​ QtLayouts.Layout.fillWidth: true
562​ rating: model.rating / 10
563​ }
564​ Kirigami.Heading {
565​ QtLayouts.Layout.fillWidth: true
566​ level: 5
567​ elide: Text.ElideRight
568​ text: i18nc("The number of times the item has been downloaded", "%1 downloads").arg(model.downloadCount)
569​ }
570​ }
571​ Item {
572​ anchors.fill: parent
573​ opacity: (model.status == NewStuff.ItemsModel.InstallingStatus || model.status == NewStuff.ItemsModel.UpdatingStatus) ? 1 : 0
574​ Behavior on opacity { NumberAnimation { duration: Kirigami.Units.longDuration; } }
575​ Rectangle {
576​ anchors.fill: parent
577​ color: Kirigami.Theme.backgroundColor
578​ opacity: 0.5;
579​ }
580​ QtControls.BusyIndicator {
581​ anchors.centerIn: parent
582​ running: parent.opacity > 0
583​ }
584​ }
585​ MouseArea {
586​ anchors.fill: parent;
587​ onClicked: tileDelegateRoot.showDetails();
588​ }
589​ }
590​ }
591​ }
592​ Component {
593​ id: thumbDelegate
594​ KCM.GridDelegate {
595​ text: model.name
596​ // onClicked: pageStack.push(detailsPage, {
597​ // name: model.name,
598​ // author: model.author,
599​ // previews: model.previews,
600​ // shortSummary: model.shortSummary,
601​ // summary: model.summary,
602​ // homepage: model.homepage,
603​ // donationLink: model.donationLink
604​ // });
605​ actions: [
606​ Kirigami.Action {
607​ text: root.useLabel
608​ iconName: "dialog-ok-apply"
609​ onTriggered: { model.adopt(model.index); }
610​ enabled: (model.status == NewStuff.ItemsModel.InstalledStatus || model.status == NewStuff.ItemsModel.UpdateableStatus) && newStuffEngine.hasAdoptionCommand
611​ visible: enabled
612​ },
613​ Kirigami.Action {
614​ text: model.downloadCount == 1 ? i18nc("Request installation of this item, available when there is exactly one downloadable item", "Install") : i18nc("Show installation options, where there is more than one downloadable item", "Install...");
615​ iconName: "install"
616​ onTriggered: {
617​ if (model.downloadCount == 1) {
618​ newStuffModel.installItem(model.index);
619​ } else {
620​ downloadItemsSheet.downloadLinks = model.downloadLinks;
621​ downloadItemsSheet.entryId = model.index;
622​ downloadItemsSheet.open();
623​ }
624​ }
625​ enabled: model.status == NewStuff.ItemsModel.DownloadableStatus || model.status == NewStuff.ItemsModel.DeletedStatus;
626​ visible: enabled;
627​ },
628​ Kirigami.Action {
629​ text: i18nc("Request updating of this item", "Update");
630​ iconName: "update"
631​ onTriggered: { newStuffModel.installItem(model.index); }
632​ enabled: model.status == NewStuff.ItemsModel.UpdateableStatus;
633​ visible: enabled;
634​ },
635​ Kirigami.Action {
636​ text: root.uninstallLabel
637​ iconName: "uninstall"
638​ onTriggered: { newStuffModel.uninstallItem(model.index); }
639​ enabled: model.status == NewStuff.ItemsModel.InstalledStatus
640​ visible: enabled;
641​ }
642​ ]
643​ thumbnailAvailable: model.previewsSmall.length > 0
644​ thumbnail: Image {
645​ anchors {
646​ fill: parent;
647​ margins: Kirigami.Units.smallSpacing;
648​ }
649​ asynchronous: true;
650​ fillMode: Image.PreserveAspectFit;
651​ source: thumbnailAvailable ? model.previewsSmall[0] : "";
652​ Kirigami.Icon {
653​ id: updateAvailableBadge;
654​ opacity: (model.status == NewStuff.ItemsModel.UpdateableStatus) ? 1 : 0;
655​ Behavior on opacity { NumberAnimation { duration: Kirigami.Units.shortDuration; } }
656​ anchors {
657​ top: parent.top;
658​ right: parent.right;
659​ margins: -Kirigami.Units.smallSpacing;
660​ }
661​ height: Kirigami.Units.iconSizes.smallMedium;
662​ width: height;
663​ source: "package-installed-outdated";
664​ }
665​ Kirigami.Icon {
666​ id: installedBadge;
667​ opacity: (model.status == NewStuff.ItemsModel.InstalledStatus) ? 1 : 0;
668​ Behavior on opacity { NumberAnimation { duration: Kirigami.Units.shortDuration; } }
669​ anchors {
670​ top: parent.top;
671​ right: parent.right;
672​ margins: -Kirigami.Units.smallSpacing;
673​ }
674​ height: Kirigami.Units.iconSizes.smallMedium;
675​ width: height;
676​ source: "package-installed-updated";
677​ }
678​ Item {
679​ anchors.fill: parent
680​ opacity: (model.status == NewStuff.ItemsModel.InstallingStatus || model.status == NewStuff.ItemsModel.UpdatingStatus) ? 1 : 0
681​ Behavior on opacity { NumberAnimation { duration: Kirigami.Units.longDuration; } }
682​ Rectangle {
683​ anchors.fill: parent
684​ color: Kirigami.Theme.backgroundColor
685​ opacity: 0.5;
686​ }
687​ QtControls.BusyIndicator {
688​ anchors.centerIn: parent
689​ running: parent.opacity > 0
690​ }
691​ }
692​ MouseArea {
693​ anchors.fill: parent;
694​ onClicked: pageStack.push(detailsPage, {
695​ newStuffModel: root.view.model,
696​ index: model.index,
697​ name: model.name,
698​ author: model.author,
699​ previews: model.previews,
700​ shortSummary: model.shortSummary,
701​ summary: model.summary,
702​ homepage: model.homepage,
703​ donationLink: model.donationLink,
704​ status: model.status,
705​ commentsCount: model.numberOfComments,
706​ rating: model.rating,
707​ downloadCount: model.downloadCount,
708​ downloadLinks: model.downloadLinks,
709​ providerId: model.providerId
710​ });
711​ }
712​ }
713​ }
714​ }
715​
716​ Component {
717​ id: detailsPage;
718​ NewStuff.EntryDetails { }
719​ }
720​}