Differential D21721 Diff 62049 src/qtquick/qml/Button.qml

Changeset View

Standalone View

View Options

src/qtquick/qml/Button.qml

  • This file was added.
1​/*
2​ * Copyright (C) 2019 Dan Leinir Turthra Jensen <admin@leinir.dk>
3​ *
4​ * This library is free software; you can redistribute it and/or
5​ * modify it under the terms of the GNU Lesser General Public
6​ * License as published by the Free Software Foundation; either
7​ * version 2.1 of the License, or (at your option) version 3, or any
8​ * later version accepted by the membership of KDE e.V. (or its
9​ * successor approved by the membership of KDE e.V.), which shall
10​ * act as a proxy defined in Section 6 of version 3 of the license.
11​ *
12​ * This library is distributed in the hope that it will be useful,
13​ * but WITHOUT ANY WARRANTY; without even the implied warranty of
14​ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15​ * Lesser General Public License for more details.
16​ *
17​ * You should have received a copy of the GNU Lesser General Public
18​ * License along with this library. If not, see <http://www.gnu.org/licenses/>.
19​ *
20​ */
21​
22​/**
23​ * @brief A button which when clicked will open a dialog with a NewStuff.Page at the base
24​ *
25​ * This component is equivalent to the old Button
26​ * @see KNewStuff::Button
27​ */
28​
29​import QtQuick 2.7
30​import QtQuick.Controls 2.5 as QtControls
31​import org.kde.newstuff 1.1 as NewStuff
32​
33​QtControls.Button {
34​ id: component
35​
36​ /**
37​ * The configuration file to use for this button
38​ */
39​ property string configFile: ghnsDialog.configFile
40​
ahiemstraUnsubmitted
Done

Any particular reason not to alias these directly to the dialog?

ahiemstra: Any particular reason not to alias these directly to the dialog?
leinirAuthorUnsubmitted
Done

Yes, if it's aliased directly, we end up initialising the engine as soon as the Button component is instantiated, which we want to avoid (as it's quite an expensive operation, and causes internet traffic the user might very well have no intention of using... which arguably is also a phone-home situation, and that needs to be avoided). I'll make an implementationy comment about that. (not really documentation relevant, but certainly relevant when someone invariably comes across this in the future and asks the same question)

leinir: Yes, if it's aliased directly, we end up initialising the engine as soon as the Button…
41​ /**
42​ * Set the text that should appear on the button. Will be set as
43​ * i18n("Download New %1").
44​ *
45​ * @note For the sake of consistency, you should NOT override the text propety, just set this one
46​ */
47​ property string downloadNewWhat: i18nc("Used to contruct the button's label (which will become Download New 'this value')", "Stuff")
48​ text: i18n("Download New %1").arg(downloadNewWhat)
49​
50​ /**
51​ * The default view mode of the dialog spawned by this button. This should be
52​ * set using the NewStuff.Page.ViewMode enum
53​ * @see NewStuff.Page.ViewMode
54​ */
55​ property alias viewMode: ghnsDialog.viewMode
56​
57​ /**
58​ * emitted when the Hot New Stuff dialog is about to be shown, usually
59​ * as a result of the user having click on the button
60​ */
61​ signal aboutToShowDialog();
62​
63​ /**
64​ * emitted when the dialog has been closed
65​ */
66​ signal dialogFinished(var changedEntries);
67​
68​ /**
69​ * If this is true (default is false), the button will be shown when the Kiosk settings are such
70​ * that Get Hot New Stuff is disallowed (and any other time enabled is set to false).
71​ * Usually you would want to leave this alone, but occasionally you may have a reason to
72​ * leave a button in place that the user is unable to enable.
73​ */
74​ property bool visibleWhenDisabled: false
75​
76​ /**
77​ * Show the dialog (same as clicking the button), if allowed by the Kiosk settings
78​ */
79​ function showDialog() {
80​ if (ghnsDialog.engine.allowedByKiosk) {
81​ ghnsDialog.engine.configFile = component.configFile
82​ component.aboutToShowDialog();
83​ ghnsDialog.open();
84​ } else {
85​ // make some noise, because silently doing nothing is a bit annoying
86​ }
87​ }
88​
89​ onClicked: { showDialog(); }
90​
91​ icon.name: "get-hot-new-stuff"
92​ visible: enabled || visibleWhenDisabled
93​ enabled: ghnsDialog.engine.allowedByKiosk
94​
95​ NewStuff.Dialog {
96​ id: ghnsDialog
97​ onDialogFinished: { component.dialogFinished(changedEntries); }
98​ }
99​}
ahiemstraUnsubmitted
Done

Hmm, this is quite tricky, as a user of the Button I can now no longer safely bind enabled as that would override the allowedByKiosk binding. You should probably make this an explicit binding so it doesn't break as easily.

ahiemstra: Hmm, this is quite tricky, as a user of the Button I can now no longer safely bind enabled as…
leinirAuthorUnsubmitted
Not Done

Humhum, yes... so it needs to be possible to change enabled from outside, but it also needs to be locked to disabled if allowedByKiosk is false... i'm thinking this probably won't be the prettiest thing, but... catch enabled changing, check whether allowedByKiosk is false and force it to false in the case it is, and otherwise ignore it... unless there's a magic trick i'm not aware of, which would be neat ;)

leinir: Humhum, yes... so it needs to be possible to change enabled from outside, but it also needs to…
ahiemstraUnsubmitted
Not Done

With a Binding object I can make sure that a button is kept disabled even when the main enabled is bound to a different value. However, I can not prevent javascript "button.enabled = true" from enabling the button, so forcing things in an enabledChanged handler seems the better solution.

ahiemstra: With a Binding object I can make sure that a button is kept disabled even when the main enabled…