Differential D12278 Diff 50181 kcms/colors/package/contents/ui/main.qml

Changeset View

Standalone View

View Options

kcms/colors/package/contents/ui/main.qml

  • This file was added.
1​/*
2​ * Copyright 2018 Kai Uwe Broulik <kde@privat.broulik.de>
3​ *
4​ * This program is free software; you can redistribute it and/or
5​ * modify it under the terms of the GNU General Public License as
6​ * published by the Free Software Foundation; either version 2 of
7​ * the License or (at your option) version 3 or any later version
8​ * accepted by the membership of KDE e.V. (or its successor approved
9​ * by the membership of KDE e.V.), which shall act as a proxy
10​ * defined in Section 14 of version 3 of the license.
11​ *
12​ * This program is distributed in the hope that it will be useful,
13​ * but WITHOUT ANY WARRANTY; without even the implied warranty of
14​ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15​ * GNU General Public License for more details.
16​ *
17​ * You should have received a copy of the GNU General Public License
18​ * along with this program. If not, see <http://www.gnu.org/licenses/>.
19​ */
20​
21​import QtQuick 2.6
22​import QtQuick.Layouts 1.1
23​import QtQuick.Window 2.2
24​import QtQuick.Dialogs 1.0 as QtDialogs
25​import QtQuick.Controls 2.3 as QtControls
26​import org.kde.kirigami 2.4 as Kirigami
27​import org.kde.kconfig 1.0 // for KAuthorized
28​import org.kde.kcm 1.1 as KCM
29​
30​KCM.GridViewKCM {
31​ KCM.ConfigModule.quickHelp: i18n("This module lets you choose the color scheme.")
GB_2Unsubmitted
Not Done

Better: "This module lets you choose the color scheme."

GB_2: Better: "This module lets you choose the color scheme."
32​
33​ view.model: kcm.colorsModel
34​ view.currentIndex: kcm.selectedSchemeIndex
35​
36​ enabled: !kcm.downloadingFile
37​
38​ Component.onCompleted: {
39​ // The thumbnails are a bit more elaborate and need more room, especially when translated
40​ view.implicitCellWidth = Kirigami.Units.gridUnit * 13;
41​ }
42​
43​ DropArea {
44​ anchors.fill: parent
45​ onEntered: {
46​ if (!drag.hasUrls) {
47​ drag.accepted = false;
48​ }
49​ }
50​ onDropped: {
51​ infoLabel.visible = false;
52​ kcm.installSchemeFromFile(drop.urls[0]);
53​ }
54​ }
55​
56​ // putting the InlineMessage as header item causes it to show up initially despite visible false
57​ header: ColumnLayout {
58​ Kirigami.InlineMessage {
59​ id: notInstalledWarning
60​ Layout.fillWidth: true
61​
62​ type: Kirigami.MessageType.Warning
63​ showCloseButton: true
64​ visible: false
65​
66​ Connections {
67​ target: kcm
68​ onShowSchemeNotInstalledWarning: {
69​ notInstalledWarning.text = i18n("The color scheme '%1' is not installed. Selecting the default theme instead.", schemeName)
70​ notInstalledWarning.visible = true;
71​ }
72​ }
davidedmundsonUnsubmitted
Not Done

It seems these should be standard across all GridView KCMs.

davidedmundson: It seems these should be standard across all GridView KCMs.
73​ }
74​ }
75​
76​ view.remove: Transition {
77​ ParallelAnimation {
78​ NumberAnimation { property: "scale"; to: 0.5; duration: Kirigami.Units.longDuration }
79​ NumberAnimation { property: "opacity"; to: 0.0; duration: Kirigami.Units.longDuration }
80​ }
81​ }
82​
83​ view.removeDisplaced: Transition {
84​ SequentialAnimation {
85​ // wait for the "remove" animation to finish
86​ PauseAnimation { duration: Kirigami.Units.longDuration }
87​ NumberAnimation { properties: "x,y"; duration: Kirigami.Units.longDuration }
88​ }
89​ }
90​
91​ view.delegate: KCM.GridDelegate {
92​ id: delegate
93​
94​ text: model.display
95​
96​ thumbnailAvailable: true
97​ thumbnail: Rectangle {
98​ anchors.fill: parent
99​
100​ opacity: model.pendingDeletion ? 0.3 : 1
101​ Behavior on opacity {
102​ NumberAnimation { duration: Kirigami.Units.longDuration }
103​ }
104​
105​ color: model.palette.window
106​
107​ Kirigami.Theme.highlightColor: model.palette.highlight
108​ Kirigami.Theme.highlightedTextColor: model.palette.highlightedText
109​ Kirigami.Theme.linkColor: model.palette.link
110​ Kirigami.Theme.textColor: model.palette.text
111​
112​ ColumnLayout {
113​ anchors {
114​ fill: parent
115​ margins: Kirigami.Units.smallSpacing
116​ }
117​
118​ RowLayout {
119​ Layout.fillWidth: true
120​
121​ QtControls.Label {
122​ Layout.fillWidth: true
123​ Layout.fillHeight: true
124​ verticalAlignment: Text.AlignVCenter
125​ text: i18n("Window text")
126​ elide: Text.ElideRight
127​ color: model.palette.windowText
128​ }
129​
130​ QtControls.Button {
131​ Layout.alignment: Qt.AlignBottom
132​ text: i18n("Button")
133​ Kirigami.Theme.backgroundColor: model.palette.button
134​ Kirigami.Theme.textColor: model.palette.buttonText
135​ activeFocusOnTab: false
136​ }
137​ }
138​
139​ QtControls.Frame {
140​ Layout.fillWidth: true
141​ Layout.fillHeight: true
142​ Kirigami.Theme.backgroundColor: model.palette.base
143​ // FIXME Make Frame still visible but without any inner padding
144​ padding: 1
145​ activeFocusOnTab: false
146​
147​ Column {
148​ id: listPreviewColumn
149​
150​ readonly property string demoText: " <a href='#'>%2</a> <a href='#'><font color='%3'>%4</font></a>"
151​ .arg(i18nc("Hyperlink", "link"))
152​ .arg(model.palette.linkVisited)
153​ .arg(i18nc("Visited hyperlink", "visited"))
154​
155​ width: parent.width
156​
157​ QtControls.ItemDelegate {
158​ width: parent.width
159​ text: i18n("Normal text") + listPreviewColumn.demoText
160​ activeFocusOnTab: false
161​ }
162​
163​ QtControls.ItemDelegate {
164​ width: parent.width
165​ highlighted: true
166​ // TODO use proper highlighted link color
167​ text: i18n("Highlighted text") + listPreviewColumn.demoText
168​ activeFocusOnTab: false
169​ }
170​
171​ QtControls.ItemDelegate {
172​ width: parent.width
173​ enabled: false
174​ text: i18n("Disabled text") + listPreviewColumn.demoText
175​ activeFocusOnTab: false
176​ }
177​ }
178​ }
179​ }
180​
181​ // Make the preview non-clickable but still reacting to hover
182​ MouseArea {
183​ anchors.fill: parent
184​ onClicked: delegate.clicked()
185​ onDoubleClicked: delegate.doubleClicked()
186​ }
187​ }
188​
189​ actions: [
190​ Kirigami.Action {
191​ iconName: "document-edit"
192​ tooltip: i18n("Edit Color Scheme")
193​ enabled: !model.pendingDeletion
194​ onTriggered: kcm.editScheme(model.index, parent)
195​ },
196​ Kirigami.Action {
197​ iconName: "edit-delete"
198​ tooltip: i18n("Remove Color Scheme")
199​ enabled: model.removable
200​ visible: !model.pendingDeletion
201​ onTriggered: kcm.setPendingDeletion(model.index, true)
202​ },
203​ Kirigami.Action {
204​ iconName: "edit-undo"
205​ tooltip: i18n("Restore Color Scheme")
206​ visible: model.pendingDeletion
207​ onTriggered: kcm.setPendingDeletion(model.index, false)
208​ }
209​ ]
210​ onClicked: {
211​ kcm.selectedScheme = model.schemeName;
212​ view.forceActiveFocus();
213​ }
214​ onDoubleClicked: {
215​ kcm.save();
216​ }
217​ }
218​
219​ footer: ColumnLayout {
220​ Kirigami.InlineMessage {
221​ id: infoLabel
222​ Layout.fillWidth: true
223​
224​ showCloseButton: true
225​
226​ Connections {
227​ target: kcm
228​ onShowSuccessMessage: {
229​ infoLabel.type = Kirigami.MessageType.Positive;
230​ infoLabel.text = message;
231​ infoLabel.visible = true;
232​ // Avoid dual message widgets
233​ notInstalledWarning.visible = false;
234​ }
235​ onShowErrorMessage: {
236​ infoLabel.type = Kirigami.MessageType.Error;
237​ infoLabel.text = message;
238​ infoLabel.visible = true;
239​ notInstalledWarning.visible = false;
240​ }
241​ }
242​ }
243​
244​ RowLayout {
245​ Layout.alignment: Qt.AlignRight
246​
247​ QtControls.Button {
248​ text: i18n("Install from File...")
249​ icon.name: "document-import"
250​ onClicked: fileDialogLoader.active = true
251​ }
252​
253​ QtControls.Button {
254​ text: i18n("Get New Color Schemes...")
255​ icon.name: "get-hot-new-stuff"
256​ onClicked: kcm.getNewStuff(this)
257​ visible: KAuthorized.authorize("ghns")
258​ }
259​ }
260​ }
261​
262​ Loader {
263​ id: fileDialogLoader
264​ active: false
265​ sourceComponent: QtDialogs.FileDialog {
266​ title: i18n("Open Color Scheme")
267​ folder: shortcuts.home
268​ nameFilters: [ i18n("Color Scheme Files (*.colors)") ]
269​ Component.onCompleted: open()
270​ onAccepted: {
271​ infoLabel.visible = false;
272​ kcm.installSchemeFromFile(fileUrls[0])
273​ fileDialogLoader.active = false
274​ }
275​ onRejected: {
276​ fileDialogLoader.active = false
277​ }
278​ }
279​ }
280​}