Differential D12278 Diff 50164 kcms/colors/package/contents/ui/main.qml

Changeset View

Standalone View

View Options

kcms/colors/package/contents/ui/main.qml

  • This file was added.
1​/*
2​ * Copyright 2018 Kai Uwe Broulik <kde@privat.broulik.de>
3​ *
4​ * This program is free software; you can redistribute it and/or
5​ * modify it under the terms of the GNU General Public License as
6​ * published by the Free Software Foundation; either version 2 of
7​ * the License or (at your option) version 3 or any later version
8​ * accepted by the membership of KDE e.V. (or its successor approved
9​ * by the membership of KDE e.V.), which shall act as a proxy
10​ * defined in Section 14 of version 3 of the license.
11​ *
12​ * This program is distributed in the hope that it will be useful,
13​ * but WITHOUT ANY WARRANTY; without even the implied warranty of
14​ * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
15​ * GNU General Public License for more details.
16​ *
17​ * You should have received a copy of the GNU General Public License
18​ * along with this program. If not, see <http://www.gnu.org/licenses/>.
19​ */
20​
21​import QtQuick 2.6
22​import QtQuick.Layouts 1.1
23​import QtQuick.Window 2.2
24​import QtQuick.Dialogs 1.0 as QtDialogs
25​import QtQuick.Controls 2.3 as QtControls
26​import org.kde.kirigami 2.4 as Kirigami
27​import org.kde.kcm 1.1 as KCM
28​
29​KCM.GridViewKCM {
30​ KCM.ConfigModule.quickHelp: i18n("This module lets you choose the color scheme.")
31​
GB_2Unsubmitted
Not Done

Better: "This module lets you choose the color scheme."

GB_2: Better: "This module lets you choose the color scheme."
32​ view.model: kcm.colorsModel
33​ view.currentIndex: kcm.selectedSchemeIndex
34​
35​ Component.onCompleted: {
36​ // The thumbnails are a bit more elaborate and need more room, especially when translated
37​ view.implicitCellWidth = Kirigami.Units.gridUnit * 13;
38​ }
39​
40​ DropArea {
41​ anchors.fill: parent
42​ onEntered: {
43​ if (!drag.hasUrls) {
44​ drag.accepted = false;
45​ }
46​ }
47​ onDropped: kcm.installSchemeFromFile(drop.urls[0])
48​ }
49​
50​ // putting the InlineMessage as header item causes it to show up initially despite visible false
51​ header: ColumnLayout {
52​ Kirigami.InlineMessage {
53​ id: notInstalledWarning
54​ Layout.fillWidth: true
55​
56​ type: Kirigami.MessageType.Warning
57​ showCloseButton: true
58​ visible: false
59​
60​ Connections {
61​ target: kcm
62​ onShowSchemeNotInstalledWarning: {
63​ notInstalledWarning.text = i18n("The color scheme '%1' is not installed. Selecting the default theme instead.", schemeName)
64​ notInstalledWarning.visible = true;
65​ }
66​ }
67​ }
68​ }
69​
70​ view.remove: Transition {
71​ ParallelAnimation {
72​ NumberAnimation { property: "scale"; to: 0.5; duration: Kirigami.Units.longDuration }
davidedmundsonUnsubmitted
Not Done

It seems these should be standard across all GridView KCMs.

davidedmundson: It seems these should be standard across all GridView KCMs.
73​ NumberAnimation { property: "opacity"; to: 0.0; duration: Kirigami.Units.longDuration }
74​ }
75​ }
76​
77​ view.removeDisplaced: Transition {
78​ SequentialAnimation {
79​ // wait for the "remove" animation to finish
80​ PauseAnimation { duration: Kirigami.Units.longDuration }
81​ NumberAnimation { properties: "x,y"; duration: Kirigami.Units.longDuration }
82​ }
83​ }
84​
85​ view.delegate: KCM.GridDelegate {
86​ id: delegate
87​
88​ text: model.display
89​
90​ thumbnailAvailable: true
91​ thumbnail: Rectangle {
92​ anchors.fill: parent
93​
94​ opacity: model.pendingDeletion ? 0.3 : 1
95​ Behavior on opacity {
96​ NumberAnimation { duration: Kirigami.Units.longDuration }
97​ }
98​
99​ color: model.palette.window
100​
101​ Kirigami.Theme.highlightColor: model.palette.highlight
102​ Kirigami.Theme.highlightedTextColor: model.palette.highlightedText
103​ Kirigami.Theme.linkColor: model.palette.link
104​ Kirigami.Theme.textColor: model.palette.text
105​
106​ ColumnLayout {
107​ anchors {
108​ fill: parent
109​ margins: Kirigami.Units.smallSpacing
110​ }
111​
112​ RowLayout {
113​ Layout.fillWidth: true
114​
115​ QtControls.Label {
116​ Layout.fillWidth: true
117​ Layout.fillHeight: true
118​ verticalAlignment: Text.AlignVCenter
119​ text: i18n("Window text")
120​ elide: Text.ElideRight
121​ color: model.palette.windowText
122​ }
123​
124​ QtControls.Button {
125​ Layout.alignment: Qt.AlignBottom
126​ text: i18n("Button")
127​ Kirigami.Theme.backgroundColor: model.palette.button
128​ Kirigami.Theme.textColor: model.palette.buttonText
129​ activeFocusOnTab: false
130​ }
131​ }
132​
133​ QtControls.Frame {
134​ Layout.fillWidth: true
135​ Layout.fillHeight: true
136​ Kirigami.Theme.backgroundColor: model.palette.base
137​ // FIXME Make Frame still visible but without any inner padding
138​ padding: 1
139​ activeFocusOnTab: false
140​
141​ Column {
142​ id: listPreviewColumn
143​
144​ readonly property string demoText: " <a href='#'>%2</a> <a href='#'><font color='%3'>%4</font></a>"
145​ .arg(i18nc("Hyperlink", "link"))
146​ .arg(model.palette.linkVisited)
147​ .arg(i18nc("Visited hyperlink", "visited"))
148​
149​ width: parent.width
150​
151​ QtControls.ItemDelegate {
152​ width: parent.width
153​ text: i18n("Normal text") + listPreviewColumn.demoText
154​ activeFocusOnTab: false
155​ }
156​
157​ QtControls.ItemDelegate {
158​ width: parent.width
159​ highlighted: true
160​ // TODO use proper highlighted link color
161​ text: i18n("Highlighted text") + listPreviewColumn.demoText
162​ activeFocusOnTab: false
163​ }
164​
165​ QtControls.ItemDelegate {
166​ width: parent.width
167​ enabled: false
168​ text: i18n("Disabled text") + listPreviewColumn.demoText
169​ activeFocusOnTab: false
170​ }
171​ }
172​ }
173​ }
174​
175​ // Make the preview non-clickable but still reacting to hover
176​ MouseArea {
177​ anchors.fill: parent
178​ onClicked: delegate.clicked()
179​ }
180​ }
181​
182​ actions: [
183​ Kirigami.Action {
184​ iconName: "document-edit"
185​ tooltip: i18n("Edit Color Scheme")
186​ enabled: !model.pendingDeletion
187​ onTriggered: kcm.editScheme(model.index, parent)
188​ },
189​ Kirigami.Action {
190​ iconName: "edit-delete"
191​ tooltip: i18n("Remove Color Scheme")
192​ enabled: model.removable
193​ visible: !model.pendingDeletion
194​ onTriggered: kcm.setPendingDeletion(model.index, true)
195​ },
196​ Kirigami.Action {
197​ iconName: "edit-undo"
198​ tooltip: i18n("Restore Color Scheme")
199​ visible: model.pendingDeletion
200​ onTriggered: kcm.setPendingDeletion(model.index, false)
201​ }
202​ ]
203​ onClicked: {
204​ kcm.selectedScheme = model.schemeName;
205​ view.forceActiveFocus();
206​ }
207​ }
208​
209​ footer: ColumnLayout {
210​ Kirigami.InlineMessage {
211​ id: infoLabel
212​ Layout.fillWidth: true
213​
214​ showCloseButton: true
215​
216​ Connections {
217​ target: kcm
218​ onShowSuccessMessage: {
219​ infoLabel.type = Kirigami.MessageType.Positive;
220​ infoLabel.text = message;
221​ infoLabel.visible = true;
222​ // Avoid dual message widgets
223​ notInstalledWarning.visible = false;
224​ }
225​ onShowErrorMessage: {
226​ infoLabel.type = Kirigami.MessageType.Error;
227​ infoLabel.text = message;
228​ infoLabel.visible = true;
229​ notInstalledWarning.visible = false;
230​ }
231​ }
232​ }
233​
234​ RowLayout {
235​ Layout.alignment: Qt.AlignRight
236​
237​ QtControls.Button {
238​ text: i18n("Install from File...")
239​ icon.name: "document-import"
240​ onClicked: fileDialogLoader.active = true
241​ }
242​
243​ QtControls.Button {
244​ text: i18n("Get New Color Schemes...")
245​ icon.name: "get-hot-new-stuff"
246​ onClicked: kcm.getNewStuff(this)
247​ }
248​ }
249​ }
250​
251​ Loader {
252​ id: fileDialogLoader
253​ active: false
254​ sourceComponent: QtDialogs.FileDialog {
255​ title: i18n("Open Color Scheme")
256​ folder: shortcuts.home
257​ nameFilters: [ i18n("Color Scheme Files (*.colors)") ]
258​ Component.onCompleted: open()
259​ onAccepted: {
260​ // should we allow installing multiple files at once?
261​ kcm.installSchemeFromFile(fileUrls[0])
262​ fileDialogLoader.active = false
263​ }
264​ onRejected: {
265​ fileDialogLoader.active = false
266​ }
267​ }
268​ }
269​}