Differential D5932 Diff 14753 kcms/nightcolor/package/contents/ui/main.qml

Changeset View

Standalone View

View Options

kcms/nightcolor/package/contents/ui/main.qml

  • This file was added.
1​/********************************************************************
2​Copyright 2017 Roman Gilg <subdiff@gmail.com>
3​
4​This program is free software; you can redistribute it and/or modify
5​it under the terms of the GNU General Public License as published by
6​the Free Software Foundation; either version 2 of the License, or
7​(at your option) any later version.
8​
9​This program is distributed in the hope that it will be useful,
10​but WITHOUT ANY WARRANTY; without even the implied warranty of
11​MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
12​GNU General Public License for more details.
13​
14​You should have received a copy of the GNU General Public License
15​along with this program. If not, see <http://www.gnu.org/licenses/>.
16​*********************************************************************/
17​import QtQuick 2.1
18​import QtQuick.Layouts 1.1
19​import QtQuick.Controls 1.4 as Controls
20​
21​import org.kde.kquickcontrolsaddons 2.0
22​import org.kde.plasma.core 2.0 as PlasmaCore
23​import org.kde.plasma.extras 2.0 as PlasmaExtras
24​
25​import org.kde.colorcorrect 0.1 as CC
26​
27​Item {
28​ id: root
29​
30​ implicitHeight: units.gridUnit * 20
31​
32​ property int error: cA.error
davidedmundsonUnsubmitted
Done

We have an actual implicitWidth from the layout itself, we don't need to guess

davidedmundson: We have an actual implicitWidth from the layout itself, we don't need to guess
33​
34​ property bool defaultRequested: false
35​
36​ CC.CompositorAdaptor {
37​ id: cA
38​ }
39​
40​ CC.Geolocator {
41​ id: locator
42​ }
43​
44​ CC.SunCalc {
45​ id: sunCalc
46​ }
47​
48​ function calcNeedsSave() {
49​ kcm.needsSave = cA.checkStaged();
50​ // If the user changes something manually again after
51​ // Default was triggered, only allow a normal
52​ // configuration change again:
53​ defaultRequested = false;
54​ }
55​
56​ Connections {
57​ target: kcm
58​ onLoadRelay: cA.reloadData()
59​ onSaveRelay: defaultRequested ? cA.sendConfigurationAll() : cA.sendConfiguration();
60​ onDefaultsRelay: {
61​ if (!cA.nightColorAvailable) {
62​ return;
63​ }
64​ activator.checked = cA.activeDefault;
65​ tempSlider.value = cA.nightTemperatureDefault;
66​ modeSwitcher.currentIndex = cA.modeDefault;
67​
68​ // set everything else to default as well
69​ cA.latitudeFixedStaged = cA.latitudeFixedDefault;
70​ cA.longitudeFixedStaged = cA.longitudeFixedDefault;
71​
72​ cA.morningBeginFixedStaged = cA.morningBeginFixedDefault;
73​ cA.eveningBeginFixedStaged = cA.eveningBeginFixedDefault;
74​ cA.transitionTimeStaged = cA.transitionTimeDefault;
75​
76​ kcm.needsSave = cA.checkStagedAll();
77​ defaultRequested = true;
78​ }
79​ }
80​
81​ Connections {
82​ target: cA
83​ onDataUpdated: calcNeedsSave()
84​ onStagedDataReset: {
85​ activator.checked = cA.active;
86​ tempSlider.value = cA.nightTemperature;
87​ modeSwitcher.currentIndex = cA.mode;
88​ reset();
89​ calcNeedsSave();
90​ }
91​ }
92​ signal reset()
93​
94​ Item {
95​ id: main
96​ width: childrenRect.width
97​ height: childrenRect.height
98​
99​ enabled: cA.nightColorAvailable
100​
101​ Controls.CheckBox {
102​ id: activator
103​ text: i18nd("kcm_nightcolor", "Activate Night Color")
104​ checked: cA.active
105​
106​ onCheckedChanged: {
107​ cA.activeStaged = checked;
108​ calcNeedsSave();
109​ }
110​ }
111​
112​ ColumnLayout {
113​ id: mainControls
114​ anchors.top: activator.bottom
115​ anchors.topMargin: units.largeSpacing
116​
117​ enabled: activator.checked
118​
119​ Controls.Label {
120​ text: i18nd("kcm_nightcolor", "Night Color Temperature: ") + tempSlider.value + i18nd("kcm_nightcolor", " K")
121​ }
122​
123​ Controls.Slider {
124​ id: tempSlider
125​ implicitWidth: units.gridUnit * 15
126​
127​ minimumValue: cA.minimalTemperature
128​ maximumValue: cA.neutralTemperature
129​ value: cA.nightTemperature
130​ stepSize: 100
131​
132​ onValueChanged: {
133​ cA.nightTemperatureStaged = value;
134​ calcNeedsSave();
135​ }
136​ }
137​
138​ RowLayout {
139​ spacing: units.largeSpacing
140​ Controls.Label {
141​ text: i18n("Operation mode:")
142​ }
143​ Controls.ComboBox {
144​ id: modeSwitcher
145​ implicitWidth: theme.mSize(theme.defaultFont).width * 9
146​ model: [i18nd("kcm_nightcolor", "Automatic"),
147​ i18nd("kcm_nightcolor", "Location"),
148​ i18nd("kcm_nightcolor", "Times")]
149​ currentIndex: cA.mode
150​ onCurrentIndexChanged: {
151​ cA.modeStaged = currentIndex;
152​ advancedControlLoader.updatePage(currentIndex);
153​ calcNeedsSave();
154​ }
155​ }
156​ }
157​ }
158​
159​ Loader {
160​ id: advancedControlLoader
161​
162​ anchors.top: mainControls.bottom
163​ anchors.topMargin: units.largeSpacing
164​
165​ function updatePage(index) {
166​ sourceComponent = undefined;
167​ var page;
168​ if (index == CC.CompositorAdaptor.ModeLocation) {
169​ page = manualLocationsView;
170​ } else if (index == CC.CompositorAdaptor.ModeTimings) {
171​ page = manualTimingsView;
172​ } else {
173​ page = automaticView;
174​ }
175​
176​ sourceComponent = page;
177​ }
178​ }
179​
180​ Component {
181​ id: automaticView
182​ Row {
183​ spacing: units.largeSpacing
184​
185​ Loader {
186​ sourceComponent: TimingsView {
187​ latitude: locator.latitude
188​ longitude: locator.longitude
189​ }
190​ }
191​ Loader {
192​ sourceComponent: LocationsAutoView {}
193​ }
194​
195​ }
196​ }
197​
198​ Component {
199​ id: manualLocationsView
200​ Row {
201​ spacing: units.largeSpacing
202​ Loader {
203​ sourceComponent: TimingsView {
204​ latitude: cA.latitudeFixedStaged
205​ longitude: cA.longitudeFixedStaged
206​
207​ Connections {
208​ target: root
209​ onReset: {
210​ latitude = cA.latitudeFixed
211​ longitude = cA.longitudeFixed
212​ }
213​ }
214​ }
215​ }
216​ Loader {
217​ sourceComponent: LocationsFixedView {}
218​ }
219​ }
220​ }
221​
222​ Component {
223​ id: manualTimingsView
224​ Column {
225​ spacing: units.smallSpacing
226​
227​ GridLayout {
228​ id: manualTimingsViewGrid
229​
230​ columns: 3
231​ rowSpacing: units.smallSpacing
232​ columnSpacing: units.smallSpacing
233​ enabled: activator.checked && cA.timingsEnabled
234​
235​ Connections {
236​ target: root
237​ onReset: {
238​ mornBeginManField.backend = cA.morningBeginFixed;
239​ evenBeginManField.backend = cA.eveningBeginFixed;
240​ transTimeField.backend = cA.transitionTime;
241​ }
242​ }
243​
244​ Controls.Label {
245​ text: i18nd("kcm_nightcolor", "Sunrise begins")
246​ Layout.alignment: Qt.AlignRight
247​ }
248​ TimeField {
249​ id: mornBeginManField
250​ backend: cA.morningBeginFixedStaged
251​ onBackendChanged: {cA.morningBeginFixedStaged = backend;
252​ calcNeedsSave();
253​ }
254​ }
255​ Controls.Label {
256​ enabled: false
257​ text: i18nd("kcm_nightcolor", "(HH:MM)")
258​ }
259​ Controls.Label {
260​ text: i18nd("kcm_nightcolor", "Sunset begins")
261​ Layout.alignment: Qt.AlignRight
262​ }
263​ TimeField {
264​ id: evenBeginManField
265​ backend: cA.eveningBeginFixedStaged
266​ onBackendChanged: {cA.eveningBeginFixedStaged = backend;
267​ calcNeedsSave();
268​ }
269​ }
270​ Controls.Label {
271​ enabled: false
272​ text: i18nd("kcm_nightcolor", "(HH:MM)")
273​ }
274​ Controls.Label {
275​ text: i18nd("kcm_nightcolor", "Transition duration")
276​ Layout.alignment: Qt.AlignRight
277​ }
278​ NumberField {
279​ id: transTimeField
280​ backend: cA.transitionTimeStaged
281​ onBackendChanged: {cA.transitionTimeStaged = backend;
282​ calcNeedsSave();
283​ }
284​
285​ inputMethodHints: Qt.ImhDigitsOnly
286​ validator: IntValidator {bottom: 1; top: 600;} // less than 12 hours (in minutes: 720)
287​ }
288​ Controls.Label {
289​ enabled: false
290​ text: i18nd("kcm_nightcolor", "(In minutes - min. 1, max. 600)")
291​ }
292​ }
293​ Controls.Label {
294​ id: manualTimingsError1
295​ anchors.horizontalCenter: manualTimingsViewGrid.horizontalCenter
296​ visible: mornBeginManField.backend - evenBeginManField.backend >= 0
297​ font.italic: true
298​ text: i18nd("kcm_nightcolor", "Error: Morning not before evening.")
299​ }
300​ Controls.Label {
301​ id: manualTimingsError2
302​ anchors.horizontalCenter: manualTimingsViewGrid.horizontalCenter
303​ visible: {
304​ if (manualTimingsError1.visible) {
305​ return false;
306​ }
307​ var trTime = transTimeField.backend * 60 * 1000;
308​ var mor = mornBeginManField.backend;
309​ var eve = evenBeginManField.backend;
310​ return eve - mor <= trTime || 86400000 - eve.getTime() + mor.getTime() <= trTime;
311​ }
312​ font.italic: true
313​ text: i18nd("kcm_nightcolor", "Error: Transition time overlaps.")
314​ }
315​ }
316​ }
317​ }
318​
319​ // error message as overlay
320​ Item {
321​ width: 0.8 * main.width
322​ height: 0.8 * main.height
323​ anchors.centerIn: main
324​
325​ visible: error != CC.CompositorAdaptor.ErrorCodeSuccess
326​
327​ Rectangle {
328​ anchors.centerIn: parent
329​ width: errorMessage.contentWidth * 1.1
330​ height: errorMessage.contentHeight * 1.1
331​ color: theme.backgroundColor
332​ opacity: 0.8
333​
334​ border {
335​ width: units.devicePixelRatio
336​ color: theme.textColor
337​ }
338​ }
339​
340​ PlasmaExtras.Heading {
341​ id: errorMessage
342​ anchors.fill: parent
343​
davidedmundsonUnsubmitted
Done

just fill the parent. It's already set to main.width*0.8

davidedmundson: just fill the parent. It's already set to main.width*0.8
344​ level: 4
345​ text: cA.errorText
346​
347​ horizontalAlignment: Text.AlignHCenter
348​ verticalAlignment: Text.AlignVCenter
349​
350​ wrapMode: Text.Wrap
351​ textFormat: Text.PlainText
352​ }
353​ }
354​}
355​