diff --git a/recipes-plasma/packagegroups/plasma-mobile.bb b/recipes-plasma/packagegroups/plasma-mobile.bb
index 956c236..f1f85f4 100644
--- a/recipes-plasma/packagegroups/plasma-mobile.bb
+++ b/recipes-plasma/packagegroups/plasma-mobile.bb
@@ -1,19 +1,20 @@
 DESCRIPTION = "KDE Plasma Mobile"
 LICENSE = "MIT"
 LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
 
 inherit packagegroup
 
 RDEPENDS_${PN} = " \
     breeze \
     kactivitymanagerd \
     kdecoration \
     kscreenlocker \
     kwayland-integration \
     kwin \
     libkscreen \
     libksysguard \
     plasma-integration \
     plasma-phone-components \
     plasma-workspace \
+    systemsettings \
 "
diff --git a/recipes-plasma/systemsettings.inc b/recipes-plasma/systemsettings.inc
new file mode 100644
index 0000000..5c2c8b6
--- /dev/null
+++ b/recipes-plasma/systemsettings.inc
@@ -0,0 +1,48 @@
+DESCRIPTION = "System Settings"
+HOMEPAGE = ""
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://COPYING;md5=5c213a7de3f013310bd272cdb6eb7a24"
+PR = "r0"
+
+DEPENDS += " \
+    kitemviews \
+    kcmutils \
+    ki18n \
+    kio \
+    kservice \
+    kiconthemes \
+    kwidgetsaddons \
+    kwindowsystem \
+    kxmlgui \
+    kdbusaddons \
+    kconfig \
+    kdoctools \
+    kpackage \
+    kdeclarative \
+    kactivities \
+    kactivitiesstats \
+    kirigami \
+"
+
+SRC_URI = " \
+    git://anongit.kde.org/${BPN};nobranch=1 \
+"
+S = "${WORKDIR}/git"
+
+inherit cmake_plasma
+
+do_compile_prepend() {
+    # desktoptojson needs to find installed service type files
+    export XDG_DATA_DIRS=${STAGING_DATADIR}:$XDG_DATA_DIRS
+    # meinproc5 needs to find its libraries
+    export LD_LIBRARY_PATH=${STAGING_LIBDIR_NATIVE}:$LD_LIBRARY_PATH
+}
+
+FILES_${PN} += " \
+    ${datadir}/kpackage/genericqml/org.kde.systemsettings.sidebar \
+    ${datadir}/kxmlgui5/systemsettings/systemsettingsui.rc \
+"
+
+RDEPENDS_${PN} += " \
+    qtquickcontrols-qmlplugins \
+"
diff --git a/recipes-plasma/systemsettings_5.11.3.bb b/recipes-plasma/systemsettings_5.11.3.bb
new file mode 100644
index 0000000..56169bb
--- /dev/null
+++ b/recipes-plasma/systemsettings_5.11.3.bb
@@ -0,0 +1,2 @@
+require ${PN}.inc
+SRCREV = "v${PV}"