diff --git a/CMakeLists.txt b/CMakeLists.txt
index 0624fff..1f731ed 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -1,61 +1,62 @@
 # The CMake version we require (must be first)
 cmake_minimum_required(VERSION 3.0.2)
 
 project(alkimia VERSION 7.0.1)
 
 find_package(ECM 0.0.11 REQUIRED NO_MODULE)
 
 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${ECM_KDE_MODULE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules)
 
 include(KDEInstallDirs)
 include(KDECMakeSettings)
 include(KDECompilerSettings NO_POLICY_SCOPE)
 include(FeatureSummary)
 
 # check for PkgConfig, Qt and MPIR/GMP
 find_package(PkgConfig)
 if(BUILD_QT4)
     find_package(Qt4 REQUIRED COMPONENTS QtCore QtDBus QtTest)
     set(QT_USE_LIBSPREFIX Qt4::Qt)
     set(ALKIMIA_LIB_SUFFIX "")
     set(ALKIMIA_INCLUDE_SUFFIX "Qt4")
     set(ALKIMIA_PATH_SUFFIX)
     set(PC_TARGET_QTPREFIX Qt)
     set(PC_TARGET_SUFFIX)
 else()
     find_package(Qt5 REQUIRED COMPONENTS Core DBus Test)
     set(QT_USE_LIBSPREFIX Qt5::)
     set(ALKIMIA_LIB_SUFFIX "5")
     set(ALKIMIA_INCLUDE_SUFFIX "Qt5")
     set(ALKIMIA_PATH_SUFFIX 5)
     set(PC_TARGET_QTPREFIX Qt5)
     set(PC_TARGET_SUFFIX 5)
 endif()
 
 # figure out which multi-precision library to use
 # MPIR is preferred over GMP
 find_package(MPIR)
 if(MPIR_FOUND)
   set(MP_INCLUDE_DIR ${MPIR_INCLUDE_DIR})
   set(MP_LIBRARIES ${MPIR_LIBRARIES})
   set(MP_HEADER mpirxx.h)
   set(MP_CMAKE_MODULE "MPIR")
   set(PC_LIB mpir)
 else()
   find_package(GMP REQUIRED)
   set(MP_INCLUDE_DIR ${GMP_INCLUDE_DIR})
   set(MP_LIBRARIES ${GMP_LIBRARIES})
   set(MP_HEADER gmpxx.h)
   set(MP_CMAKE_MODULE "GMP")
   set(PC_LIB gmp)
 endif()
 
 # check for Doxygen (for API documentation)
 find_package(Doxygen)
 
 feature_summary(WHAT ALL)
 
 add_definitions(-DQT_USE_FAST_CONCATENATION -DQT_USE_FAST_OPERATOR_PLUS)
+include_directories(${MP_INCLUDE_DIR})
 
 add_subdirectory(src)
 add_subdirectory(autotests)
diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
index 91cb472..a2379ed 100644
--- a/src/CMakeLists.txt
+++ b/src/CMakeLists.txt
@@ -1,106 +1,105 @@
 include(GenerateExportHeader)
 include(ECMGenerateHeaders)
 include(ECMGeneratePriFile)
 include(CMakePackageConfigHelpers)
 include(ECMSetupVersion)
 
 set(ALKIMIA_LIB_VERSION ${alkimia_VERSION})
 set(ALKIMIA_LIB_SOVERSION "${alkimia_VERSION_MAJOR}")
 
 set(alkimia_LIB_SRCS
   alkvalue.cpp
   alkquoteitem.cpp
   alkcompany.cpp
   )
 
 set(alkimia_HEADERS
   ${CMAKE_CURRENT_BINARY_DIR}/alkvalue.h
   alkquoteitem.h
   alkcompany.h
   ${CMAKE_CURRENT_BINARY_DIR}/alk_export.h
   )
 
 add_library(alkimia SHARED ${alkimia_LIB_SRCS})
 
 kde_target_enable_exceptions(alkimia PUBLIC)
 
-target_include_directories(alkimia PRIVATE ${MP_INCLUDE_DIR})
 target_link_libraries(alkimia PUBLIC ${QT_USE_LIBSPREFIX}Core ${QT_USE_LIBSPREFIX}DBus ${MP_LIBRARIES})
 generate_export_header(alkimia BASE_NAME alk)
 
 if(WIN32)
     set_target_properties(alkimia PROPERTIES SUFFIX "${ALKIMIA_LIB_SOVERSION}${CMAKE_SHARED_LIBRARY_SUFFIX}")
 else()
     set_target_properties(alkimia PROPERTIES VERSION ${ALKIMIA_LIB_VERSION} SOVERSION ${ALKIMIA_LIB_SOVERSION})
 endif()
 set_target_properties(alkimia PROPERTIES OUTPUT_NAME alkimia${ALKIMIA_LIB_SUFFIX})
 set(INCLUDE_INSTALL_DIR include/alkimia/${ALKIMIA_INCLUDE_SUFFIX})
 
 if (NOT WIN32)
    configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libalkimia.pc.in ${CMAKE_CURRENT_BINARY_DIR}/libalkimia${ALKIMIA_PATH_SUFFIX}.pc IMMEDIATE @ONLY)
 endif(NOT WIN32)
 configure_file(${CMAKE_CURRENT_SOURCE_DIR}/alkvalue.h.in ${CMAKE_CURRENT_BINARY_DIR}/alkvalue.h IMMEDIATE)
 
 ########### create package configuration file ###########
 
 # create a Config.cmake and a ConfigVersion.cmake file and install them
 set(CMAKECONFIG_INSTALL_DIR "${CMAKECONFIG_INSTALL_PREFIX}/LibAlkimia${ALKIMIA_PATH_SUFFIX}-${alkimia_VERSION_MAJOR}.${alkimia_VERSION_MINOR}")
 
 ecm_setup_version(${alkimia_VERSION} VARIABLE_PREFIX ALKIMIA
   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/LibAlkimia${ALKIMIA_PATH_SUFFIX}ConfigVersion.cmake"
   COMPATIBILITY SameMajorVersion
 )
 
 configure_package_config_file(
   "${CMAKE_CURRENT_SOURCE_DIR}/LibAlkimiaConfig.cmake.in"
   "${CMAKE_CURRENT_BINARY_DIR}/LibAlkimia${ALKIMIA_PATH_SUFFIX}Config.cmake"
   INSTALL_DESTINATION ${CMAKECONFIG_INSTALL_DIR}
   PATH_VARS INCLUDE_INSTALL_DIR
 )
 
 ########### install files ###############
 
 install(TARGETS alkimia
         EXPORT  alkimiaTargets
         ${INSTALL_TARGETS_DEFAULT_ARGS}
         )
 
 export(TARGETS alkimia
        FILE "${CMAKE_CURRENT_BINARY_DIR}/LibAlkimia${ALKIMIA_PATH_SUFFIX}Targets.cmake"
        NAMESPACE Alkimia::
       )
 
 install(EXPORT alkimiaTargets
         FILE LibAlkimia${ALKIMIA_PATH_SUFFIX}Targets.cmake
         NAMESPACE Alkimia::
         DESTINATION ${CMAKECONFIG_INSTALL_DIR}
        )
 
 install(FILES ${alkimia_HEADERS}
         DESTINATION ${INCLUDE_INSTALL_DIR}/alkimia
         COMPONENT Devel)
 
 install(FILES
           "${CMAKE_CURRENT_BINARY_DIR}/LibAlkimia${ALKIMIA_PATH_SUFFIX}Config.cmake"
           "${CMAKE_CURRENT_BINARY_DIR}/LibAlkimia${ALKIMIA_PATH_SUFFIX}ConfigVersion.cmake"
           "../cmake/modules/Find${MP_CMAKE_MODULE}.cmake"
         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
         COMPONENT Devel)
 
 if (NOT WIN32)
   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/libalkimia${ALKIMIA_PATH_SUFFIX}.pc
           DESTINATION ${LIB_INSTALL_DIR}/pkgconfig)
 endif(NOT WIN32)
 
 ########### documentation ###################
 
 if(DOXYGEN_FOUND)
   set(APIDOC_DIR ${CMAKE_CURRENT_BINARY_DIR}/apidocs)
 
   make_directory(${APIDOC_DIR})
 
   configure_file(${CMAKE_CURRENT_SOURCE_DIR}/libalkimia.doxygen.in ${CMAKE_CURRENT_BINARY_DIR}/libalkimia.doxygen IMMEDIATE)
 
   add_custom_target(libalkimia_apidoc ${DOXYGEN} ${CMAKE_CURRENT_BINARY_DIR}/libalkimia.doxygen)
 endif(DOXYGEN_FOUND)