diff --git a/CMakeLists.txt b/CMakeLists.txt
index b05688e..2dbbbb4 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -1,175 +1,175 @@
 cmake_minimum_required(VERSION 3.5)
 
 set(KF5_VERSION "5.67.0") # handled by release scripts
 set(KF5_DEP_VERSION "5.66.0") # handled by release scripts
 project(KNotifications VERSION ${KF5_VERSION})
 
 # ECM setup
 include(FeatureSummary)
 find_package(ECM 5.66.0  NO_MODULE)
 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://commits.kde.org/extra-cmake-modules")
 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
 
 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/cmake/modules)
 
 
 include(GenerateExportHeader)
 include(ECMSetupVersion)
 include(ECMGenerateHeaders)
 include(ECMQtDeclareLoggingCategory)
 include(ECMPoQmTools)
 include(ECMAddQch)
 include(ECMGenerateExportHeader)
 
 set(EXCLUDE_DEPRECATED_BEFORE_AND_AT 0 CACHE STRING "Control the range of deprecated API excluded from the build [default=0].")
 
 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
 
 ecm_setup_version(PROJECT
   VARIABLE_PREFIX KNOTIFICATIONS
   VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/knotifications_version.h"
   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5NotificationsConfigVersion.cmake"
 
                         SOVERSION 5)
 
 # Dependencies
 set(REQUIRED_QT_VERSION 5.12.0)
 set(CMAKE_AUTORCC TRUE)
 
 find_package(Qt5 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Widgets)
 
-if (NOT ANDROID)
+if (NOT ANDROID AND NOT WIN32)
     find_package(Qt5 ${REQUIRED_QT_VERSION} CONFIG REQUIRED DBus)
-else ()
+elseif (ANDROID)
     find_package(Qt5 ${REQUIRED_QT_VERSION} CONFIG REQUIRED AndroidExtras)
     find_package(Gradle REQUIRED)
 endif()
 
 find_package(Qt5 ${REQUIRED_QT_VERSION} QUIET OPTIONAL_COMPONENTS TextToSpeech)
 set_package_properties(Qt5TextToSpeech PROPERTIES
    DESCRIPTION "Qt text to speech module"
    TYPE OPTIONAL
    PURPOSE "Required to build text to speech notification support")
 if (Qt5TextToSpeech_FOUND)
   add_definitions(-DHAVE_SPEECH)
 endif()
 
 include(KDEInstallDirs)
 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
 include(KDECMakeSettings)
 
 if (NOT APPLE AND NOT WIN32)
     find_package(X11)
 endif()
 
 set(HAVE_X11 ${X11_FOUND})
 set(HAVE_XTEST ${X11_XTest_FOUND})
 if(X11_FOUND)
    find_package(Qt5X11Extras ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
 endif()
 if(APPLE)
    find_package(Qt5MacExtras ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
 endif()
 if (WIN32)
     find_package(LibSnoreToast REQUIRED)
     set_package_properties(LibSnoreToast PROPERTIES TYPE REQUIRED
                             PURPOSE     "for the Windows Toast Notifications"
-                            DESCRIPTION "A command line application, capable of creating 
+                            DESCRIPTION "A command line application, capable of creating
                                         Windows Toast notifications on Windows (>=)8 "
     )
     find_package(Qt5Network REQUIRED)
 endif()
 
 set(HAVE_KWINDOWSYSTEM FALSE)
-if(NOT ANDROID)
+if(NOT ANDROID AND NOT WIN32)
     find_package(KF5WindowSystem ${KF5_DEP_VERSION} REQUIRED)
     set(HAVE_KWINDOWSYSTEM TRUE)
 endif()
 
 find_package(KF5Config ${KF5_DEP_VERSION} REQUIRED)
 find_package(KF5Codecs ${KF5_DEP_VERSION} REQUIRED)
 find_package(KF5CoreAddons ${KF5_DEP_VERSION} REQUIRED)
 
 if (NOT WIN32 AND NOT ANDROID)
     find_package(Qt5 ${REQUIRED_QT_VERSION} CONFIG REQUIRED DBus)
     find_package(Canberra)
     set_package_properties(Canberra PROPERTIES
         PURPOSE "Needed to build audio notification support"
         TYPE OPTIONAL)
     if (Canberra_FOUND)
         add_definitions(-DHAVE_CANBERRA)
     else()
         # This is REQUIRED since you cannot tell CMake "either one of those two optional ones are required"
         find_package(Phonon4Qt5 4.6.60 NO_MODULE REQUIRED)
         set_package_properties(Phonon4Qt5 PROPERTIES
             DESCRIPTION "Qt-based audio library"
             PURPOSE "Needed to build audio notification support when Canberra isn't available")
         add_definitions(-DHAVE_PHONON4QT5)
     endif()
 endif()
 
 set(HAVE_DBUS FALSE)
 if (TARGET Qt5::DBus)
     find_package(dbusmenu-qt5 CONFIG)
     set_package_properties(dbusmenu-qt5 PROPERTIES DESCRIPTION "DBusMenuQt"
                             URL "https://launchpad.net/libdbusmenu-qt" TYPE OPTIONAL
                             PURPOSE "Support for notification area menus via the DBusMenu protocol")
 
     set(HAVE_DBUS TRUE)
 endif()
 
 remove_definitions(-DQT_NO_CAST_FROM_BYTEARRAY)
 #add_definitions(-DQT_NO_FOREACH)
 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
     ecm_install_po_files_as_qm(po)
 endif()
 if (NOT APPLE) # QtMac::setBadgeLabelText is deprecated
 add_definitions(-DQT_DISABLE_DEPRECATED_BEFORE=0x050d00)
 endif()
 add_definitions(-DKF_DISABLE_DEPRECATED_BEFORE_AND_AT=0x054200)
 add_subdirectory(src)
 if (BUILD_TESTING)
     add_subdirectory(tests)
     add_subdirectory(autotests)
 endif()
 
 # create a Config.cmake and a ConfigVersion.cmake file and install them
 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5Notifications")
 
 if (BUILD_QCH)
     ecm_install_qch_export(
         TARGETS KF5Notifications_QCH
         FILE KF5NotificationsQchTargets.cmake
         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
         COMPONENT Devel
     )
     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5NotificationsQchTargets.cmake\")")
 endif()
 
 include(CMakePackageConfigHelpers)
 
 configure_package_config_file(
   "${CMAKE_CURRENT_SOURCE_DIR}/KF5NotificationsConfig.cmake.in"
   "${CMAKE_CURRENT_BINARY_DIR}/KF5NotificationsConfig.cmake"
   PATH_VARS KDE_INSTALL_DBUSINTERFACEDIR
   INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
 )
 
 install(FILES
   "${CMAKE_CURRENT_BINARY_DIR}/KF5NotificationsConfig.cmake"
   "${CMAKE_CURRENT_BINARY_DIR}/KF5NotificationsConfigVersion.cmake"
   DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
   COMPONENT Devel
 )
 
 install(EXPORT KF5NotificationsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5NotificationsTargets.cmake NAMESPACE KF5:: )
 
 install(FILES
    ${CMAKE_CURRENT_BINARY_DIR}/knotifications_version.h
   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5} COMPONENT Devel
 )
 install(FILES knotifications.categories  DESTINATION  ${KDE_INSTALL_LOGGINGCATEGORIESDIR})
 
 
 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)
diff --git a/src/CMakeLists.txt b/src/CMakeLists.txt
index 522b860..e1675e8 100644
--- a/src/CMakeLists.txt
+++ b/src/CMakeLists.txt
@@ -1,231 +1,231 @@
 if (Phonon4Qt5_FOUND)
     include_directories(${PHONON_INCLUDE_DIR})
 endif()
 if (CANBERRA_FOUND)
     include_directories(${CANBERRA_INCLUDE_DIRS})
 endif()
 
 ecm_create_qm_loader(knotifications_QM_LOADER knotifications5_qt)
 
 set(knotifications_SRCS
 
   knotification.cpp
   knotificationmanager.cpp
   kpassivepopup.cpp
 
   knotifyconfig.cpp
   knotificationplugin.cpp
   notifybyexecute.cpp
   notifybylogfile.cpp
   notifybytaskbar.cpp
   ${knotifications_QM_LOADER}
 )
 
 if (TARGET Qt5::DBus)
   list(APPEND knotifications_SRCS
     kstatusnotifieritem.cpp
     kstatusnotifieritemdbus_p.cpp
     knotificationrestrictions.cpp
 
     imageconverter.cpp #needed to marshal images for sending over dbus by NotifyByPopup
     notifybypopup.cpp
     notifybyportal.cpp
   )
 endif()
 
 if (ANDROID)
     add_subdirectory(android)
     list(APPEND knotifications_SRCS notifybyandroid.cpp knotifications.qrc)
 endif()
 
 if (WIN32)
   list(APPEND knotifications_SRCS notifybysnore.cpp)
 endif ()
 
 if (APPLE)
   list(APPEND knotifications_SRCS notifybymacosnotificationcenter.mm)
 endif()
 
 ecm_qt_declare_logging_category(knotifications_SRCS HEADER debug_p.h IDENTIFIER LOG_KNOTIFICATIONS CATEGORY_NAME org.kde.knotifications)
 
 if (Canberra_FOUND)
   set(knotifications_SRCS ${knotifications_SRCS}
   notifybyaudio_canberra.cpp)
 elseif (Phonon4Qt5_FOUND)
   set(knotifications_SRCS ${knotifications_SRCS}
   notifybyaudio_phonon.cpp)
 endif()
 
 if (Qt5TextToSpeech_FOUND)
   set(knotifications_SRCS ${knotifications_SRCS}
     notifybytts.cpp)
 endif()
 
 if (TARGET Qt5::DBus)
   if (dbusmenu-qt5_FOUND)
     message("dbusmenu-qt5_FOUND")
     set(HAVE_DBUSMENUQT 1)
     include_directories(${dbusmenu-qt5_INCLUDE_DIRS})
   else()
     set(HAVE_DBUSMENUQT 0)
   endif()
 
   qt5_add_dbus_adaptor(knotifications_SRCS     org.kde.StatusNotifierItem.xml
                     kstatusnotifieritemdbus_p.h KStatusNotifierItemDBus)
 
 
   set(statusnotifierwatcher_xml org.kde.StatusNotifierWatcher.xml)
   qt5_add_dbus_interface(knotifications_SRCS ${statusnotifierwatcher_xml} statusnotifierwatcher_interface)
   set(notifications_xml org.freedesktop.Notifications.xml)
   qt5_add_dbus_interface(knotifications_SRCS ${notifications_xml} notifications_interface)
 endif()
 
 configure_file(config-knotifications.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/config-knotifications.h )
 
 add_library(KF5Notifications ${knotifications_SRCS})
 add_library(KF5::Notifications ALIAS KF5Notifications)
 
 ecm_generate_export_header(KF5Notifications
     EXPORT_FILE_NAME knotifications_export.h
     BASE_NAME KNotifications
     GROUP_BASE_NAME KF
     VERSION ${KF5_VERSION}
     DEPRECATED_BASE_VERSION 0
     DEPRECATION_VERSIONS 5.67
     EXCLUDE_DEPRECATED_BEFORE_AND_AT ${EXCLUDE_DEPRECATED_BEFORE_AND_AT}
 )
 
 target_include_directories(KF5Notifications INTERFACE "$<INSTALL_INTERFACE:${KDE_INSTALL_INCLUDEDIR_KF5}/KNotifications>")
 
 target_link_libraries(KF5Notifications PUBLIC
    Qt5::Widgets
 )
 if (TARGET Qt5::DBus)
    target_link_libraries(KF5Notifications PUBLIC Qt5::DBus)
 endif()
 target_link_libraries(KF5Notifications PRIVATE
    KF5::CoreAddons
    KF5::ConfigCore
    KF5::Codecs
 )
 
-if (NOT ANDROID)
+if (TARGET KF5::WindowSystem)
     target_link_libraries(KF5Notifications PRIVATE KF5::WindowSystem)
 endif()
 
 if (TARGET SnoreToast::SnoreToastActions)
   target_link_libraries(KF5Notifications PRIVATE Qt5::Network SnoreToast::SnoreToastActions)
 endif ()
 
 if (Phonon4Qt5_FOUND)
     target_link_libraries(KF5Notifications PRIVATE
         ${PHONON_LIBRARIES})
 endif()
 
 if (Canberra_FOUND)
     target_link_libraries(KF5Notifications PRIVATE
         Canberra::Canberra)
 endif()
 
 if (Qt5TextToSpeech_FOUND)
     target_link_libraries(KF5Notifications PRIVATE Qt5::TextToSpeech)
 endif()
 
 if(X11_FOUND)
    target_link_libraries(KF5Notifications PRIVATE ${X11_X11_LIB} Qt5::X11Extras)
 endif()
 
 if(APPLE)
   target_link_libraries(KF5Notifications PRIVATE Qt5::MacExtras "-framework Foundation" "-framework AppKit")
 endif()
 
 if(X11_XTest_FOUND)
   target_link_libraries(KF5Notifications PRIVATE ${X11_XTest_LIB})
 endif()
 
 if(HAVE_DBUSMENUQT)
   target_link_libraries(KF5Notifications PRIVATE dbusmenu-qt5)
 endif()
 
 if (ANDROID)
     target_link_libraries(KF5Notifications PRIVATE Qt5::AndroidExtras)
 endif()
 
 set_target_properties(KF5Notifications PROPERTIES VERSION   ${KNOTIFICATIONS_VERSION_STRING}
                                                   SOVERSION ${KNOTIFICATIONS_SOVERSION}
                                                   EXPORT_NAME Notifications
 )
 
 ecm_generate_headers(KNotifications_HEADERS
   HEADER_NAMES
   KNotification
   KPassivePopup
   KStatusNotifierItem
   KNotificationRestrictions
   KNotificationPlugin
   KNotifyConfig
 
   REQUIRED_HEADERS KNotifications_HEADERS
 )
 
 install(TARGETS KF5Notifications EXPORT KF5NotificationsTargets ${KF5_INSTALL_TARGETS_DEFAULT_ARGS})
 
 install(FILES
   ${CMAKE_CURRENT_BINARY_DIR}/knotifications_export.h
   ${KNotifications_HEADERS}
   DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/KNotifications COMPONENT Devel
 )
 
 if(BUILD_QCH)
     ecm_add_qch(
         KF5Notifications_QCH
         NAME KNotifications
         BASE_NAME KF5Notifications
         VERSION ${KF5_VERSION}
         ORG_DOMAIN org.kde
         SOURCES # using only public headers, to cover only public API
             ${KNotifications_HEADERS}
         MD_MAINPAGE "${CMAKE_SOURCE_DIR}/README.md"
         IMAGE_DIRS "${CMAKE_SOURCE_DIR}/docs/pics"
         LINK_QCHS
             Qt5Widgets_QCH
         INCLUDE_DIRS
             ${CMAKE_CURRENT_BINARY_DIR}
         BLANK_MACROS
             KNOTIFICATIONS_EXPORT
             KNOTIFICATIONS_DEPRECATED
             KNOTIFICATIONS_DEPRECATED_EXPORT
             "KNOTIFICATIONS_DEPRECATED_VERSION(x, y, t)"
         TAGFILE_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
         QCH_INSTALL_DESTINATION ${KDE_INSTALL_QTQCHDIR}
         COMPONENT Devel
     )
 endif()
 
 if (TARGET Qt5::DBus)
     install(FILES
         org.kde.StatusNotifierItem.xml
         DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
         RENAME kf5_org.kde.StatusNotifierItem.xml)
 
     install(FILES
         org.kde.StatusNotifierWatcher.xml
         DESTINATION ${KDE_INSTALL_DBUSINTERFACEDIR}
         RENAME kf5_org.kde.StatusNotifierWatcher.xml)
 endif()
 
 install(FILES
     knotificationplugin.desktop
     DESTINATION ${KDE_INSTALL_KSERVICETYPES5DIR})
 
 include(ECMGeneratePriFile)
 ecm_generate_pri_file(BASE_NAME KNotifications LIB_NAME KF5Notifications DEPS "widgets" FILENAME_VAR PRI_FILENAME INCLUDE_INSTALL_DIR ${KDE_INSTALL_INCLUDEDIR_KF5}/KNotifications)
 install(FILES ${PRI_FILENAME} DESTINATION ${ECM_MKSPECS_INSTALL_DIR})
 
 if (ANDROID)
     if (Qt5Core_VERSION VERSION_LESS 5.14.0)
         install(FILES KF5Notifications-android-dependencies.xml DESTINATION ${KDE_INSTALL_LIBDIR})
     else()
         install(FILES KF5Notifications-android-dependencies.xml DESTINATION ${KDE_INSTALL_LIBDIR} RENAME KF5Notifications_${CMAKE_ANDROID_ARCH_ABI}-android-dependencies.xml)
     endif()
 endif()