diff --git a/CMakeLists.txt b/CMakeLists.txt
index 3267f71..1a80fdd 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -1,111 +1,126 @@
 cmake_minimum_required(VERSION 3.0)
 
 set(KF5_VERSION "5.43.0") # handled by release scripts
 project(KCoreAddons VERSION ${KF5_VERSION})
 
 include(FeatureSummary)
 find_package(ECM 5.43.0  NO_MODULE)
 set_package_properties(ECM PROPERTIES TYPE REQUIRED DESCRIPTION "Extra CMake Modules." URL "https://projects.kde.org/projects/kdesupport/extra-cmake-modules")
 feature_summary(WHAT REQUIRED_PACKAGES_NOT_FOUND FATAL_ON_MISSING_REQUIRED_PACKAGES)
 
 
 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${ECM_KDE_MODULE_DIR} ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
 
 
 include(GenerateExportHeader)
 include(CMakePackageConfigHelpers)
 include(ECMSetupVersion)
 include(ECMGenerateHeaders)
 include(ECMQtDeclareLoggingCategory)
 include(ECMAddQch)
 
 include(KDEInstallDirs)
 include(KDEFrameworkCompilerSettings NO_POLICY_SCOPE)
 include(KDECMakeSettings)
 
 option(BUILD_QCH "Build API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)" OFF)
 add_feature_info(QCH ${BUILD_QCH} "API documentation in QCH format (for e.g. Qt Assistant, Qt Creator & KDevelop)")
 
 set(REQUIRED_QT_VERSION 5.7.0)
 find_package(Qt5 ${REQUIRED_QT_VERSION} CONFIG REQUIRED Core)
 
+# TODO: create ECM macro for automoc & json things
 set(KCoreAddons_AUTOMOC_MACRO_NAMES "K_PLUGIN_FACTORY_WITH_JSON" "K_PLUGIN_FACTORY" "K_PLUGIN_CLASS_WITH_JSON")
 if(NOT CMAKE_VERSION VERSION_LESS "3.10.0")
   # CMake 3.9+ warns about automoc on files without Q_OBJECT, and doesn't know about other macros.
   # 3.10+ lets us provide more macro names that require automoc.
   list(APPEND CMAKE_AUTOMOC_MACRO_NAMES ${KCoreAddons_AUTOMOC_MACRO_NAMES})
 endif()
+set(KCoreAddons_AUTOMOC_MACRO_NAMES_WITH_JSON_ARG2 "K_PLUGIN_FACTORY_WITH_JSON" "K_PLUGIN_CLASS_WITH_JSON")
+if(NOT CMAKE_VERSION VERSION_LESS "3.9.0")
+    # CMake's automoc needs help to find names of plugin metadata files in case Q_PLUGIN_METADATA
+    # is indirectly used via other C++ preprocessor macros
+    # 3.9+ lets us provide some filter rule pairs (keyword, regexp) to match the names of such files
+    # in the plain text of the sources. See AUTOMOC_DEPEND_FILTERS docs for details.
+    foreach(macro_name  ${KCoreAddons_AUTOMOC_MACRO_NAMES_WITH_JSON_ARG2})
+        list(APPEND CMAKE_AUTOMOC_DEPEND_FILTERS
+            "${macro_name}"
+            "[\n^][ \t]*${macro_name}[ \t\n]*\\([^,]*,[ \t\n]*\"([^\"]+)\""
+        )
+    endforeach()
+endif()
+
 
 find_package(Threads)
 
 # Configure checks for kdirwatch
 find_package(FAM)
 
 set_package_properties(FAM PROPERTIES
      PURPOSE "Provides file alteration notification facilities using a separate service. FAM provides additional support for NFS.")
 
 set(HAVE_FAM ${FAM_FOUND})
 
 option(ENABLE_INOTIFY "Try to use inotify for directory monitoring" ON)
 if(ENABLE_INOTIFY)
     # Find libinotify
     find_package(Inotify)
     set_package_properties(Inotify PROPERTIES
         PURPOSE "Filesystem alteration notifications using inotify")
     set(HAVE_SYS_INOTIFY_H ${Inotify_FOUND})
 else()
     set(HAVE_SYS_INOTIFY_H FALSE)
 endif()
 
 # Generate io/config-kdirwatch.h
 configure_file(src/lib/io/config-kdirwatch.h.cmake ${CMAKE_CURRENT_BINARY_DIR}/src/lib/io/config-kdirwatch.h)
 
 include(ECMPoQmTools)
 
 ecm_setup_version(PROJECT VARIABLE_PREFIX KCOREADDONS
                         VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/kcoreaddons_version.h"
                         PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5CoreAddonsConfigVersion.cmake"
                         SOVERSION 5)
 
 
 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
     ecm_install_po_files_as_qm(po)
 endif()
 
 kde_enable_exceptions()
 
 add_subdirectory(src)
 add_subdirectory(autotests)
 add_subdirectory(tests)
 
 # create a Config.cmake and a ConfigVersion.cmake file and install them
 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5CoreAddons")
 
 if (BUILD_QCH)
     ecm_install_qch_export(
         TARGETS KF5CoreAddons_QCH
         FILE KF5CoreAddonsQchTargets.cmake
         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
         COMPONENT Devel
     )
     set(PACKAGE_INCLUDE_QCHTARGETS "include(\"\${CMAKE_CURRENT_LIST_DIR}/KF5CoreAddonsQchTargets.cmake\")")
 endif()
 
 configure_package_config_file("${CMAKE_CURRENT_SOURCE_DIR}/KF5CoreAddonsConfig.cmake.in"
                               "${CMAKE_CURRENT_BINARY_DIR}/KF5CoreAddonsConfig.cmake"
                               INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
                               )
 
 install(FILES  "${CMAKE_CURRENT_BINARY_DIR}/KF5CoreAddonsConfig.cmake"
                "${CMAKE_CURRENT_BINARY_DIR}/KF5CoreAddonsConfigVersion.cmake"
                "${CMAKE_CURRENT_SOURCE_DIR}/KF5CoreAddonsMacros.cmake"
         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
         COMPONENT Devel )
 
 install(EXPORT KF5CoreAddonsTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5CoreAddonsTargets.cmake NAMESPACE KF5:: )
 install(EXPORT KF5CoreAddonsToolingTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5CoreAddonsToolingTargets.cmake NAMESPACE KF5:: )
 
 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/kcoreaddons_version.h
         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5} COMPONENT Devel )
 
 feature_summary(WHAT ALL FATAL_ON_MISSING_REQUIRED_PACKAGES)
diff --git a/KF5CoreAddonsConfig.cmake.in b/KF5CoreAddonsConfig.cmake.in
index 7601a89..9a800ed 100644
--- a/KF5CoreAddonsConfig.cmake.in
+++ b/KF5CoreAddonsConfig.cmake.in
@@ -1,28 +1,37 @@
 @PACKAGE_INIT@
 
 include(CMakeFindDependencyMacro)
 find_dependency(Qt5Core @REQUIRED_QT_VERSION@)
 
 
 if(NOT CMAKE_VERSION VERSION_LESS "3.10.0")
   # CMake 3.9+ warns about automoc on files without Q_OBJECT, and doesn't know about other macros.
   # 3.10+ lets us provide more macro names that require automoc.
   list(APPEND CMAKE_AUTOMOC_MACRO_NAMES @KCoreAddons_AUTOMOC_MACRO_NAMES@)
 endif()
+if(NOT CMAKE_VERSION VERSION_LESS "3.9.0")
+    foreach(macro_name  @KCoreAddons_AUTOMOC_MACRO_NAMES_WITH_JSON_ARG2@)
+        # tell automoc how to find names of plugin metadata files
+        list(APPEND CMAKE_AUTOMOC_DEPEND_FILTERS
+            "${macro_name}"
+            "[\n^][ \t]*${macro_name}[ \t\n]*\\([^,]*,[ \t\n]*\"([^\"]+)\""
+        )
+    endforeach()
+endif()
 
 if(CMAKE_CROSSCOMPILING AND KF5_HOST_TOOLING)
     find_file(TARGETSFILE KF5CoreAddons/KF5CoreAddonsToolingTargets.cmake
         PATHS ${KF5_HOST_TOOLING} ${CMAKE_CURRENT_LIST_DIR}
         NO_DEFAULT_PATH
         NO_CMAKE_FIND_ROOT_PATH)
     include("${TARGETSFILE}")
 else()
     include("${CMAKE_CURRENT_LIST_DIR}/KF5CoreAddonsToolingTargets.cmake")
     if(CMAKE_CROSSCOMPILING AND DESKTOPTOJSON_EXECUTABLE)
         set_target_properties(KF5::desktoptojson PROPERTIES IMPORTED_LOCATION_NONE ${DESKTOPTOJSON_EXECUTABLE})
         set_target_properties(KF5::desktoptojson PROPERTIES IMPORTED_LOCATION ${DESKTOPTOJSON_EXECUTABLE})
     endif()
 endif()
 include("${CMAKE_CURRENT_LIST_DIR}/KF5CoreAddonsTargets.cmake")
 include("${CMAKE_CURRENT_LIST_DIR}/KF5CoreAddonsMacros.cmake")
 @PACKAGE_INCLUDE_QCHTARGETS@