diff --git a/autotests/CMakeLists.txt b/autotests/CMakeLists.txt
index baef66d32..616cb1049 100644
--- a/autotests/CMakeLists.txt
+++ b/autotests/CMakeLists.txt
@@ -1,79 +1,79 @@
 find_package(Qt5Test ${REQUIRED_QT_VERSION} REQUIRED NO_MODULE)
 set_package_properties(Qt5Test PROPERTIES PURPOSE "Required for tests")
 
 set(EXECUTABLE_OUTPUT_PATH ${CMAKE_CURRENT_BINARY_DIR})
 
 include(ECMMarkAsTest)
 include(ECMAddTests)
 
 find_package(KF5CoreAddons REQUIRED)
 find_package(KF5XmlGui REQUIRED)
 find_package(Qt5Widgets REQUIRED)
 
 # add_definitions( -DKDESRCDIR=${CMAKE_CURRENT_SOURCE_DIR} )
 
 if(KDE_PLATFORM_FEATURE_BINARY_COMPATIBLE_FEATURE_REDUCTION)
     set(PLASMA_NO_KIO TRUE)
     set(PLASMA_NO_PACKAGEKIT TRUE)
     set(PLASMA_NO_PACKAGE_EXTRADATA TRUE)
 endif()
 
 MACRO(PLASMA_UNIT_TESTS)
        FOREACH(_testname ${ARGN})
                set(libs Qt5::Qml Qt5::Test KF5::Plasma KF5::PlasmaQuick
                         KF5::Archive KF5::CoreAddons KF5::ConfigGui KF5::I18n
                         KF5::KIOCore KF5::Service KF5::IconThemes
-                        KF5::Declarative)
+                        KF5::Declarative KF5::WindowSystem)
                if(QT_QTOPENGL_FOUND)
                    list(APPEND libs Qt5::OpenGL)
                endif()
                ecm_add_test(${_testname}.cpp
                             LINK_LIBRARIES ${libs}
                             NAME_PREFIX "plasma-")
                target_include_directories(${_testname} PRIVATE "$<BUILD_INTERFACE:$<TARGET_PROPERTY:KF5PlasmaQuick,INCLUDE_DIRECTORIES>>;")
        ENDFOREACH(_testname)
 ENDMACRO(PLASMA_UNIT_TESTS)
 
 PLASMA_UNIT_TESTS(
     dialogqmltest
     dialogstatetest
     fallbackpackagetest
     packagestructuretest
     pluginloadertest
     framesvgtest
     iconitemtest
     themetest
     configmodeltest
     #    plasmoidpackagetest
 )
 
 set(storagetest_libs Qt5::Gui Qt5::Test Qt5::Sql KF5::KIOCore KF5::Plasma KF5::CoreAddons)
 if(QT_QTOPENGL_FOUND)
     list(APPEND storagetest_libs Qt5::OpenGL)
 endif()
 set(storagetest_srcs storagetest.cpp ../src/plasma/private/storage.cpp ../src/plasma/private/storagethread.cpp ../src/plasma/debug_p.cpp)
 ecm_add_test(${storagetest_srcs} TEST_NAME plasma-storagetest LINK_LIBRARIES ${storagetest_libs})
 
 if(HAVE_X11)
     set(dialognativetest_srcs dialognativetest.cpp)
     ecm_add_test(${dialognativetest_srcs} TEST_NAME dialognativetest LINK_LIBRARIES Qt5::Gui Qt5::Test Qt5::Qml Qt5::Quick KF5::WindowSystem KF5::Plasma KF5::PlasmaQuick)
 endif()
 
 set(coronatest_srcs coronatest.cpp)
 qt5_add_resources(coronatest_srcs coronatestresources.qrc)
 ecm_add_test(${coronatest_srcs} TEST_NAME coronatest LINK_LIBRARIES Qt5::Gui Qt5::Widgets Qt5::Test KF5::KIOCore KF5::Plasma KF5::CoreAddons KF5::XmlGui)
 
 set(sortfiltermodeltest_srcs
     sortfiltermodeltest.cpp
     ../src/declarativeimports/core/datamodel.cpp
     ../src/declarativeimports/core/datasource.cpp
     )
 ecm_add_test(${sortfiltermodeltest_srcs} TEST_NAME plasma-sortfiltermodeltest LINK_LIBRARIES KF5::Plasma Qt5::Gui Qt5::Test KF5::I18n KF5::Service Qt5::Qml)
 
 
 #Add a test that i18n is not used directly in any import.
 # It should /always/ be i18nd
 find_program(SH bash)
 if(SH)
     add_test(i18ndcheck ${SH} ${CMAKE_CURRENT_SOURCE_DIR}/i18ndcheck.sh ${CMAKE_SOURCE_DIR}/src/declarativeimports)
 endif()
diff --git a/src/plasmaquick/CMakeLists.txt b/src/plasmaquick/CMakeLists.txt
index 5db6edbec..e86c920e9 100644
--- a/src/plasmaquick/CMakeLists.txt
+++ b/src/plasmaquick/CMakeLists.txt
@@ -1,116 +1,116 @@
 if(HAVE_X11 AND XCB_XCB_FOUND AND XCB_SHAPE_FOUND)
     add_definitions(-DHAVE_XCB_SHAPE=1)
 else()
     add_definitions(-DHAVE_XCB_SHAPE=0)
 endif()
 
 set(plasmaquick_LIB_SRC
     appletquickitem.cpp
     dialog.cpp
     dialogshadows.cpp
     view.cpp
     containmentview.cpp
     configmodel.cpp
     shellpluginloader.cpp
     configview.cpp
     packageurlinterceptor.cpp
     private/configcategory_p.cpp
     private/packages.cpp
     ../declarativeimports/core/framesvgitem.cpp
     ../declarativeimports/core/units.cpp
 )
 
 add_library(KF5PlasmaQuick SHARED ${plasmaquick_LIB_SRC})
 add_library(KF5::PlasmaQuick ALIAS KF5PlasmaQuick)
 target_include_directories(KF5PlasmaQuick PUBLIC "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR};${CMAKE_CURRENT_BINARY_DIR}/..>")
 
 target_link_libraries(KF5PlasmaQuick
     PUBLIC
         Qt5::Gui
         Qt5::Quick
         Qt5::Qml
         KF5::Plasma
-        KF5::WindowSystem
     PRIVATE
+        KF5::WindowSystem
         KF5::KIOWidgets
         KF5::I18n
         KF5::IconThemes
         KF5::Service
         KF5::CoreAddons
         KF5::XmlGui
         KF5::Declarative
         KF5::QuickAddons
 )
 
 if(HAVE_KWAYLAND)
     target_link_libraries(KF5PlasmaQuick
         PRIVATE
         KF5::WaylandClient
     )
 endif()
 
 if(HAVE_X11)
     target_link_libraries(KF5PlasmaQuick
         PRIVATE
             Qt5::X11Extras
             ${X11_LIBRARIES}
             XCB::XCB
     )
 
     if(XCB_SHAPE_FOUND)
         target_link_libraries(KF5PlasmaQuick PRIVATE XCB::SHAPE)
     endif()
 endif()
 
 set_target_properties(KF5PlasmaQuick PROPERTIES
                                      VERSION ${PLASMA_VERSION_STRING}
                                      SOVERSION ${PLASMA_SOVERSION}
                                      EXPORT_NAME PlasmaQuick
                       )
 
 install(TARGETS KF5PlasmaQuick EXPORT KF5PlasmaQuickTargets ${KF5_INSTALL_TARGETS_DEFAULT_ARGS})
 
 generate_export_header(KF5PlasmaQuick BASE_NAME PlasmaQuick)
 
 set(plasmaquick_LIB_INCLUDES
     ${CMAKE_CURRENT_BINARY_DIR}/plasmaquick_export.h
     packageurlinterceptor.h
 )
 
 ecm_generate_headers(PlasmaQuick_CamelCase_HEADERS
     HEADER_NAMES
         AppletQuickItem
         ContainmentView
         ConfigView
         ConfigModel
         Dialog
     REQUIRED_HEADERS plasmaquick_LIB_INCLUDES
     PREFIX PlasmaQuick
 )
 
 install(FILES ${plasmaquick_LIB_INCLUDES}
         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/plasmaquick COMPONENT Devel)
 
 install(FILES ${PlasmaQuick_CamelCase_HEADERS}
         DESTINATION ${KDE_INSTALL_INCLUDEDIR_KF5}/PlasmaQuick COMPONENT Devel)
 
 set(CMAKECONFIG_INSTALL_DIR "${KDE_INSTALL_CMAKEPACKAGEDIR}/KF5PlasmaQuick")
 
 configure_package_config_file(
     "${CMAKE_CURRENT_SOURCE_DIR}/KF5PlasmaQuickConfig.cmake.in"
     "${CMAKE_CURRENT_BINARY_DIR}/KF5PlasmaQuickConfig.cmake"
     INSTALL_DESTINATION  ${CMAKECONFIG_INSTALL_DIR}
     PATH_VARS  KF5_INCLUDE_INSTALL_DIR CMAKE_INSTALL_PREFIX
 )
 
 ecm_setup_version(${KF5_VERSION}
                   VARIABLE_PREFIX PLASMAQUICK
                   PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5PlasmaQuickConfigVersion.cmake" )
 
 install(FILES
     "${CMAKE_CURRENT_BINARY_DIR}/KF5PlasmaQuickConfig.cmake"
     "${CMAKE_CURRENT_BINARY_DIR}/KF5PlasmaQuickConfigVersion.cmake"
     DESTINATION "${CMAKECONFIG_INSTALL_DIR}" COMPONENT Devel
 )
 
 install(EXPORT KF5PlasmaQuickTargets DESTINATION "${CMAKECONFIG_INSTALL_DIR}" FILE KF5PlasmaQuickTargets.cmake NAMESPACE KF5:: )