diff --git a/CMakeLists.txt b/CMakeLists.txt
index 74dc042..7e72ee7 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -1,85 +1,85 @@
 project(SyntaxHighlighting)
 
 cmake_minimum_required(VERSION 2.8.12)
 
 find_package(ECM 5.26.0 REQUIRED NO_MODULE)
 set(CMAKE_MODULE_PATH ${ECM_MODULE_PATH} ${ECM_KDE_MODULE_DIR})
 if(POLICY CMP0063)
     cmake_policy(SET CMP0063 NEW)
 endif()
 
 include(FeatureSummary)
 include(GenerateExportHeader)
 include(ECMSetupVersion)
 include(ECMGenerateHeaders)
 include(ECMGeneratePriFile)
 include(ECMPackageConfigHelpers)
 include(ECMPoQmTools)
 include(ECMQtDeclareLoggingCategory)
 include(KDEInstallDirs)
 include(KDEFrameworkCompilerSettings)
 include(KDECMakeSettings)
 
 set(KF5_VERSION "5.27.0")
 
 ecm_setup_version(${KF5_VERSION}
     VARIABLE_PREFIX SyntaxHighlighting
     VERSION_HEADER "${CMAKE_CURRENT_BINARY_DIR}/syntaxhighlighting_version.h"
     PACKAGE_VERSION_FILE "${CMAKE_CURRENT_BINARY_DIR}/KF5SyntaxHighlightingConfigVersion.cmake"
 )
 
 #
 # Dependencies
 #
 set(REQUIRED_QT_VERSION "5.6.0")
 find_package(Qt5 ${REQUIRED_QT_VERSION} NO_MODULE REQUIRED COMPONENTS Gui Network Test)
 find_package(Qt5 ${REQUIRED_QT_VERSION} NO_MODULE QUIET OPTIONAL_COMPONENTS Widgets XmlPatterns)
 set_package_properties(Qt5 PROPERTIES URL "http://qt-project.org/")
 
 find_package(Perl REQUIRED)
 set_package_properties(Perl PROPERTIES PURPOSE "Auto-generate PHP syntax definition files.")
 
 #
 # Translations
 #
 if (IS_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}/po")
     ecm_install_po_files_as_qm(po)
 endif()
 
 #
 # Actually build the stuff
 #
 include_directories(${CMAKE_CURRENT_BINARY_DIR})
 add_subdirectory(data)
 add_subdirectory(src)
 add_subdirectory(autotests)
 add_subdirectory(tests)
 
 #
 # CMake package config file generation
 #
 set(CMAKECONFIG_INSTALL_DIR "${CMAKECONFIG_INSTALL_PREFIX}/KF5SyntaxHighlighting")
 
 ecm_configure_package_config_file(
     "${CMAKE_CURRENT_SOURCE_DIR}/KF5SyntaxHighlightingConfig.cmake.in"
     "${CMAKE_CURRENT_BINARY_DIR}/KF5SyntaxHighlightingConfig.cmake"
     INSTALL_DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
 )
 
 install(FILES
         "${CMAKE_CURRENT_BINARY_DIR}/KF5SyntaxHighlightingConfig.cmake"
         "${CMAKE_CURRENT_BINARY_DIR}/KF5SyntaxHighlightingConfigVersion.cmake"
         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
         COMPONENT Devel)
 
 install(EXPORT KF5SyntaxHighlightingTargets
         DESTINATION "${CMAKECONFIG_INSTALL_DIR}"
         FILE KF5SyntaxHighlightingTargets.cmake
         NAMESPACE KF5::)
 
 install(FILES "${CMAKE_CURRENT_BINARY_DIR}/syntaxhighlighting_version.h"
-        DESTINATION "${INCLUDE_INSTALL_DIR}"
+        DESTINATION "${KDE_INSTALL_INCLUDEDIR_KF5}"
         COMPONENT Devel)
 install(FILES org_kde_syntax-highlighting.categories DESTINATION ${KDE_INSTALL_CONFDIR})
 
 feature_summary(WHAT ALL INCLUDE_QUIET_PACKAGES FATAL_ON_MISSING_REQUIRED_PACKAGES)